.SUBCKT FDME1034CZT_Q1 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                     FDME1034CZT Spice model                  **
**						Q1 : N-ch, Q2: P-ch                     **
**                    Revision RevA, 5 May 2010                 **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.565e-9
Ldrain 2 5 0.011e-9
Lsource 3 7 0.387e-9
RLgate 1 9 5.65
RLdrain 2 5 0.11
RLsource 3 7 3.87
Rgate 9 6 2.27
It 7 17 1
Ebreak 11 7 17 7 23.3
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-0.75e-6)
.MODEL DbodyMOD D (IS=22.5e-12 n=0.93 RS=24e-2 TRS1=0.05e-3 TRS2=1e-6
+ CJO=0.06e-9 M=0.55 TT=1e-9 XTI=-13)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 11.019e-3
Rdrain 5 16 RdrainMOD 34e-3
.MODEL RdrainMOD RES (TC1=3.3e-3 TC2=5.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.243 L=1.15e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=162e-10
+ XJ=0.4e-6
+ NCH=1.45e17
*Channel Current
+ U0=700 VSAT=500000 DROUT=2.5
+ DELTA=0.2 PSCBE2=0.00001 RSH=11.019e-3
*Threshold voltage
+ VTH0=0.8
*Sub-threshold characteristics
+ VOFF=-0.12 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.255e-6 DLC=0.255e-6 
+ CGSO=250e-12 CGSL=0 CGDO=15e-12 CGDL=750e-12
+ CJ=0 CF=0 CKAPPA=0.5
* Temperature parameters 
+ KT1=-0.6 KT2=0 UA1=7.75e-9
+ NJ=10)
.ENDS FDME1034CZT_Q1

.SUBCKT FDME1034CZT_Q2 2 1 3
*Nom Temp 25 deg C
Dbody 5 7 DbodyMOD 
Dbreak 7 11 DbreakMOD 
Lgate 1 9 0.675e-9
Ldrain 2 5 0.011e-9
Lsource 3 7 0.44e-9
RLgate 1 9 6.75
RLdrain 2 5 0.11
RLsource 3 7 4.4
Rgate 9 6 15.84
It 7 17 1
Ebreak 5 11 17 7 -22
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.66e-3 TC2=-0.4e-6)
.MODEL DbodyMOD D (IS=0.3e-9 n=1 RS=260e-3 TRS1=5e-3 TRS2=10e-6
+ CJO=0.09e-9 M=0.7 TT=20e-9 XTI=-10)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 15.134e-3
Rdrain 5 16 RdrainMOD 63.0e-3
.MODEL RdrainMOD RES (TC1=3.2e-3 TC2=2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.37 L=1.56e-6 NRS=0 NRD=0
.MODEL Bsim3 PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=160e-10 ;Oxide thickness
+ XJ=0.26e-6 ;Channel depth
+ NCH=1.95e17 ;Channel concentration
*Channel Current
+ U0=200 VSAT=500000 DROUT=1.8
+ DELTA=0.45 PSCBE2=0.00001 RSH=15.134e-3
*Threshold voltage
+ VTH0=-0.5
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.55e-6 DLC=0.55e-6 
+ CGSO=120e-12 CGSL=0 CGDO=41.6e-12 CGDL=1001e-12 
+ CJ=0 CF=0 CKAPPA=0.2
* Temperature parameters 
+ KT1=-0.67 KT2=0 UA1=8.4e-9
+ NJ=10)
.ENDS FDME1034CZT_Q2