* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMC8678S 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dschottky 7 5 DSchottkyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 1.275e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.158e-9
RLgate 1 9 12.75
RLdrain 2 5 0.05
RLsource 3 7 1.58
Rgate 9 6 0.8
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.25e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=2.9e-12 n=1 RS=3.12E-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=1.02e-9 M=0.35 TT=0.1n XTI=1)
.MODEL DSchottkyMOD D (IS=3.31e-6 n=1 RS=4.3e-2 TRS1=1.5e-3 TRS2=1e-6
+ CJO=1.02e-9 M=0.35 TT=0.0001n XTI=-19)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 3.15m
.MODEL RdrainMOD RES (TC1=5.8e-3 TC2=3.2e-6)
M_BSIM3 16 6 7 7 Bsim3 W=3.294 L=0.81e-6 NRS=1 NRD=0
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.58u ;Channel depth
+ NCH=2.1e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1.2
+ DELTA=0.1 PSCBE2=1e-5 RSH=0.35e-3   
**Threshold voltage
+ VTH0=1.4
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.11u DLC=0.11u 
+ CGSO=70p CGSL=0 CGDO=11p CGDL=95p
+ CJ=0 CF=0 CKAPPA=2.2
** Temperature parameters
+ KT1=-1 KT2=0 UA1=1.1e-9
+ NJ=10)
.ENDS
*FDDMC8678S(Rev.A1) 1/18/2008
*ST
*$