.SUBCKT FDMC86520DC 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2012 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC86520DC Spice model                 **
**                    Revision RevA, 9 June 2012                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.517e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.142e-9
RLgate 1 9 5.17
RLdrain 2 5 0.04
RLsource 3 7 1.42
Rgate 9 6 0.58
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.86
C_C1 6 101 275e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=2.07e-9 M=0.49 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 65.1
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.5e-3 TC2=-0.3e-6)
.MODEL DbodyMOD D (IS=0.75e-12 n=1 RS=1.6e-3 TRS1=4e-3 TRS2=1e-6 
+ CJO=0.61e-9 M=0.37 TT=3e-9 XTI=4)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.489e-3
Rdrain 5 16 RdrainMOD 2.7e-3
.MODEL RdrainMOD RES (TC1=6.2e-3 TC2=23e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=3.74117647058824 L=0.85e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10
+ XJ=0.26e-6
+ NCH=1.47e17
+ U0=780 VSAT=500000 DROUT=1.2
+ DELTA=0.14 PSCBE2=0 RSH=0.489e-3
+ VTH0=3.89
+ VOFF=-0.1 NFACTOR=1.4
+ LINT=0.085e-6 DLC=0.085e-6 
+ CGSO=296e-12 CGSL=0 CGDO=1e-12 CGDL=113e-12 
+ CJ=0 CF=0 CKAPPA=1
+ KT1=-2.25 KT2=0 UA1=3e-9
+ NJ=10)
.ENDS   
*