* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMC8651 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 1.375e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.055e-9
RLgate 1 9 13.75
RLdrain 2 5 0.05
RLsource 3 7 0.55
Rgate 9 6 0.8
Ebreak 11 7 17 7 33
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=6.5e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=8.532e-12 n=1 RS=2.83E-3 TRS1=2.5e-3 TRS2=1e-6
+ CJO=1.95e-9 M=0.42 TT=0.1e-9 XTI=1
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 2.62e-3
.MODEL RdrainMOD RES (TC1=3.5e-3 TC2=3.1e-6)
M_BSIM3 16 6 7 7 Bsim3 W=3.67 L=0.82e-6 NRS=1 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=240e-10 ;Oxide thickness
+ XJ=0.7u ;Channel depth
+ NCH=2.29e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1
+ DELTA=0.1 PSCBE2=0 RSH=0.799e-3   
**Threshold voltage
+ VTH0=0.95
**Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.145e-6 DLC=0.145e-6 
+ CGSO=92e-12 CGSL=0 CGDO=12e-12 CGDL=127e-12
+ CJ=0 CF=0 CKAPPA=2.2
** Temperature parameters
+ KT1=-0.8 KT2=0 UA1=3.5e-9
+ NJ=10)
.ENDS
*FDMC8651(Rev.A) 7/3/2008
*ST
*$