.SUBCKT FDMC86265P 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC86265P Spice model                	**
**                    Revision RevA, 01 July 2014               **
******************************************************************
+ params: tau=80 igain=1200 fs=195
+ toxgd=1000e-10 vpgd=29 multgd=2.58 areagd={0.237657142857143*0.16e-6} nsubgd=1.75e22
+ mjgd=0.535 nsubredgd=20 tr1gd=0.5 tr2gd=100
+ toxsh=7000e-10 vpsh=30 multsh=1.13 areash={0.237657142857143*3.51e-6} nsubsh=1.5e22
+ mjsh=0.6 nsubredsh=11 tr1sh=0.55 tr2sh=1000
*Nom Temp 25 deg C
Dbreak 7 11 DbreakMOD 
Lgate 1 9 2.036e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.59e-9
RLgate 1 9 20.36
RLdrain 2 5 0.05
RLsource 3 7 5.9
Rgate 9 6 3.0
X_Cgd 6 5 2 cjv params: tox={toxgd} mult={multgd} area={areagd} nsub={nsubgd}
+ mj={mjgd} vp={vpgd} nsubred={nsubredgd} tr1={tr1gd} tr2={tr2gd}
H1   161 141 V_H1 {tau}
V_H1 151 5 0V
V10  7 161 0
F1   5 161 V_F1 {-igain}
V_F1 171 141 0V
D3   151 161 Dbody_trr
.MODEL Dbody_trr D (IS=0.1e-12 n=1.04 RS=45e-3 TRS1=3.85e-3 TRS2=1e-6 
+ CJO=0.065e-9 M=0.55 TT=0 XTI=5.0)
R9   131 171  {tau*fs}
C2   161 131  1p
X_Csh 101 5 2 cjv params: tox={toxsh} mult={multsh} area={areash} nsub={nsubsh}
+ mj={mjsh} vp={vpsh} nsubred={nsubredsh} tr1={tr1sh} tr2={tr2sh}
R_R1 101 7 6.83
C_C1 6 101 8.89e-12
It 7 17 1
Ebreak 5 11 17 7 -165
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.8e-3 TC2=-1e-6)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 4.866e-3
Rdrain 5 16 RdrainMOD 820e-3
.MODEL RdrainMOD RES (TC1=7e-3 TC2=13e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.237657142857143 L=1.24e-6 NRS=0 NRD=0
.MODEL Bsim3 PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10 
+ XJ=0.35e-6 
+ NCH=1.2e17 
+ U0=350 VSAT=500000 DROUT=1.8
+ DELTA=0.05 PSCBE2=0 RSH=4.866e-3
+ VTH0=-2.75
+ VOFF=-0.08 NFACTOR=0.8
+ LINT=0.28e-6 DLC=0.28e-6 
+ CGSO=485e-12 CGSL=0 CGDO=0 CGDL=0 
+ CJ=0 CF=0 CKAPPA=1
+ KT1=-1.45 KT2=0 UA1=0.2e-9
+ NJ=10)
.ENDS
*
.subckt cjv b g c params:
+ tox=5e-10 vp=200 mult=1 area=1e-6 vfb=0 nsub=1e22 mj=0.5
+ csm=0.1 cref=1e-12 nsubred=100 tr1=0.5 tr2=100
+ am1=0 am2=1.5
.param
+ QQ_NIST2004=1.60217653e-19
+ EPS_OX=3.45313324863e-11
+ EPS_SI=1.035939974589e-10
+ cox={((EPS_OX)/tox)}
+ vj={((((QQ_NIST2004)*nsub)*(EPS_SI))*(tox**2))/(2*((EPS_OX)**2))}
+ nsubnorm=1e20
+ anorm=1.0e-12
+ n1={nsub}
+ n2={nsub/nsubred}
+ b={n2-(n2-n1)*(1+tr1)/2/tr1}
+ slope={(n2-n1)/vp/2/tr1}
.func MINA(x,y,a) {(0.5*((x)+(y)-sqrt(((x)-(y))*((x)-(y))+(a))))}
.func MAXA(x,y,a) {(0.5*((x)+(y)+sqrt(((x)-(y))*((x)-(y))+(a))))}
edummy dummy 0 value={am1*pwrs(((v(b,c)-vp)),am2)}
earea area 0 value={(area/anorm+MAXA(0,v(dummy),0))}
enmax nmax 0 value={MINA(n1/nsubnorm,(slope*v(b,c)+b)/nsubnorm,tr2)}
enmin nsub 0 value={MAXA(n2/nsubnorm,v(nmax),tr2)}
evj vj 0 value={((((QQ_NIST2004)*v(nsub)*nsubnorm)*(EPS_SI))*(tox**2))/(2*((EPS_OX)**2))}
e1 gc 0 g b 1
cref gc n1 {cref}
vref n1 0 0
evlim vlim 0 value={MAXA((1-(v(g,b)-vfb)/v(vj)),1,csm)}
gcap g b value={mult*v(area)*anorm*cox/(v(vlim))**mj/cref*v(x)}
fdummy 0 x vref 1
rdummy x 0 1
.ends cjv