.SUBCKT FDMC86260 2 1 3
+ params: tau=120 igain=320 fs=220 
+ toxgd=1000e-10 vpgd=18 multgd=1 areagd={2.38*0.13e-6*1.63} vfbgd=0 nsubgd=1.3e22
+ mjgd=0.33 csmgd=0.1 crefgd=1e-12 nsubredgd=350 tr1gd=0.4 tr2gd=120
+ toxsh=5000e-10 vpsh=15 multsh=1 areash={2.38*2e-6*1.44} vfbsh=0 nsubsh=1e22
+ mjsh=0.3 csmsh=0.1 crefsh=01e-12 nsubredsh=1200 tr1sh=0.5 tr2sh=300
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC86260 Spice model                   **
**                    Revision Rev-A, 21 Dec 2012               **
**        Rev-D, 30 Jan 2014 w/Improved capacitance model       **
******************************************************************
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.517e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.074e-9
RLgate 1 9 5.17
RLdrain 2 5 0.04
RLsource 3 7 0.74
Rgate 9 6 0.46
X_Cgd 2 1 3 cjv params: tox={toxgd} mult={multgd} area={areagd} vfb={vfbgd} nsub={nsubgd}
+ mj={mjgd} csm={csmgd} vp={vpgd} cref={crefgd} nsubred={nsubredgd} tr1={tr1gd} tr2={tr2gd}
H1   161 141 V_H1 {tau}
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 {-igain}
V_F1 171 141 0V
D2   151 161 DbodyMOD
.MODEL DbodyMOD D (IS=2.5e-12 n=1 RS=1.7e-3 TRS1=2.5e-3 TRS2=1e-6
+ CJO=5.6e-10 M=0.48 TT=0 XTI=4.3)
R9   131 171  {tau*fs}
C2   161 131  1p
X_Csh 5 101 3 cjv params: tox={toxsh} mult={multsh} area={areash} vfb={vfbsh} nsub={nsubsh}
+ mj={mjsh} csm={csmsh} vp={vpsh} cref={crefsh} nsubred={nsubredsh} tr1={tr1sh} tr2={tr2sh}
R_R1 101 7 0.5
C_C1 6 101 90e-12
It 7 17 1
Ebreak 11 7 17 7 159.5
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.77e-3 TC2=-0.8e-6)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.132e-3
Rdrain 5 16 RdrainMOD 23.7e-3
.MODEL RdrainMOD RES (TC1=9e-3 TC2=33e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.38 L=1.1e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10
+ XJ=0.54e-6
+ NCH=0.8e17
+ U0=670 VSAT=500000 DROUT=1.8
+ DELTA=0.07 PSCBE2=0 RSH=0.132e-3
+ VTH0=3.38
+ VOFF=-0.22 NFACTOR=1.2
+ LINT=0.19e-6 DLC=0.19e-6
+ CGSO=185e-12 CGSL=0 CGDO=0 CGDL=0
+ CJ=0 CF=0 CKAPPA=0.25
+ KT1=-1.6 KT2=0 UA1=1e-9
+ NJ=10)
.ENDS FDMC86260

.subckt cjv b g c params:
+ tox=5e-10 vp=200 mult=1 area=1e-6 vfb=0 nsub=1e22 mj=0.5
+ csm=0.1 cref=1e-12 nsubred=100 tr1=0.5 tr2=100
+ am1=0 am2=1.5
.param
+ QQ_NIST2004=1.60217653e-19
+ EPS_OX=3.45313324863e-11
+ EPS_SI=1.035939974589e-10
+ cox={((EPS_OX)/tox)}
+ vj={((((QQ_NIST2004)*nsub)*(EPS_SI))*(tox**2))/(2*((EPS_OX)**2))}
+ nsubnorm=1e20
+ anorm=1.0e-12
+ n1={nsub}
+ n2={nsub/nsubred}
+ b={n2-(n2-n1)*(1+tr1)/2/tr1}
+ slope={(n2-n1)/vp/2/tr1}
.func MINA(x,y,a) {(0.5*((x)+(y)-sqrt(((x)-(y))*((x)-(y))+(a))))}
.func MAXA(x,y,a) {(0.5*((x)+(y)+sqrt(((x)-(y))*((x)-(y))+(a))))}
edummy dummy 0 value={am1*pwrs(((v(b,c)-vp)),am2)}
earea area 0 value={(area/anorm+MAXA(0,v(dummy),0))}
enmax nmax 0 value={MINA(n1/nsubnorm,(slope*v(b,c)+b)/nsubnorm,tr2)}
enmin nsub 0 value={MAXA(n2/nsubnorm,v(nmax),tr2)}
evj vj 0 value={((((QQ_NIST2004)*v(nsub)*nsubnorm)*(EPS_SI))*(tox**2))/(2*((EPS_OX)**2))}
e1 gc 0 g b 1
cref gc n1 {cref}
vref n1 0 0
evlim vlim 0 value={MAXA((1-(v(g,b)-vfb)/v(vj)),1,csm)}
gcap g b value={mult*v(area)*anorm*cox/(v(vlim))**mj/cref*v(x)}
fdummy 0 x vref 1
rdummy x 0 1
.ends cjv