* PSpice Model Editor - Version 16.3.0
*$
.SUBCKT FDMC86244 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC86244 Spice model                   **
**                      Revision RevA, 23 November 2010         **
******************************************************************		
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 1.735e-9		
Ldrain 2 5 0.005e-9		
Lsource 3 7 0.565e-9		
RLgate 1 9 17.35		
RLdrain 2 5 0.05		
RLsource 3 7 5.65		
Rgate 9 6 0.3
* Shielded  Gate  		
D_D1 100 5 D_SG_cap		
D_D2 100 101 D_SG_cap		
R_R1 101 7 1		
C_C1 6 101 27e-12		
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=0.27e-9 M=0.6 t_abs=25) 		
It 7 17 1		
Ebreak 11 7 17 7 160.4		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.72e-3 TC2=-0.8e-6)		
.MODEL DbodyMOD D (IS=1.6e-12 n=1 RS=14e-3 TRS1=1.7e-3 TRS2=1e-6 		
+ CJO=0.11e-9 M=0.55 TT=1e-9 XTI=2)	;0.32	
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 1.607e-3		
Rdrain 5 16 RdrainMOD 88.2e-3		
.MODEL RdrainMOD RES (TC1=7.9e-3 TC2=25e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=0.486272 L=1.25e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=1000e-10 ;Oxide thickness		
+ XJ=0.54e-6 ;Channel depth		
+ NCH=0.6e17 ;Channel concentration		
*Channel Current		
+ U0=950 VSAT=500000 DROUT=1.8		
+ DELTA=0.07 PSCBE2=0 RSH=1.607e-3		
*Threshold voltage		
+ VTH0=3.36		
*Sub-threshold characteristics		
+ VOFF=-0.45 NFACTOR=1		
*Junction diodes and Capacitance		
+ LINT=0.225e-6 DLC=0.225e-6 		
+ CGSO=246e-12 CGSL=0 CGDO=1.2e-12 CGDL=257e-12 ;307		
+ CJ=0 CF=0 CKAPPA=0.25		
* Temperature parameters 		
+ KT1=-1.55 KT2=0 UA1=0.2e-9		
+ NJ=10)		
.ENDS   		
* 	
*$