.SUBCKT FDMC86160 2 1 3
+ params: tau=40 igain=400 fs=600
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2012 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                    FDMC86160 Spice model                     **
**                    Revision RevB, 24 Oct 2014                **
******************************************************************
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.517e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.052e-9
RLgate 1 9 5.17
RLdrain 2 5 0.41
RLsource 3 7 0.52
Rgate 9 6 0.37
H1   161 141 V_H1 {tau}
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 {-igain}
V_F1 171 141 0V
D2   151 161 DbodyMOD
.MODEL DbodyMOD D (IS=0.725e-12 n=1 RS=1.5e-3 TRS1=3.5e-3 TRS2=1e-6
+ CJO=0.4e-9 M=0.28 TT=0 XTI=4.2)
R9   131 171  {tau*fs}
C2   161 131  1p
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.37
C_C1 6 101 117e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.2e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 108.35
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.71e-3 TC2=-0.38e-6)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.489e-3
Rdrain 5 16 RdrainMOD 7.4e-3;1.455e-3
.MODEL RdrainMOD RES (TC1=7.5e-3 TC2=24e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.38 L=1.15e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10
+ XJ=0.62e-6
+ NCH=0.94e17
+ U0=700 VSAT=500000 DROUT=1.8
+ DELTA=0.04 PSCBE2=0 RSH=0.489e-3
+ VTH0=3.45
+ VOFF=-0.13 NFACTOR=1.3
+ LINT=0.175e-6 DLC=0.175e-6
+ CGSO=110e-12 CGSL=0 CGDO=0.5e-12 CGDL=145e-12
+ CJ=0 CF=0 CKAPPA=1
+ KT1=-2 KT2=0 UA1=7e-9
+ NJ=10)
.ENDS