.SUBCKT FDMC86116LZ 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2011 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC86116LZ Spice model                 **
**                    Revision RevA, 30 Oct 2011                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.714e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.51e-9
RLgate 1 9 27.14
RLdrain 2 5 1
RLsource 3 7 5.1
Rgate 9 6 0.62
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.54
C_C1 6 101 13e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=0.54e-3 CJO=0.21e-9 M=0.5 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 111.2
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-0.25e-6)
.MODEL DbodyMOD D (IS=0.5e-12 n=1.05 RS=15e-3 TRS1=2.5e-3 TRS2=1e-6
+ CJO=0.066e-9 M=0.38 TT=1e-9 XTI=3.3)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 4.167e-3
Rdrain 5 16 RdrainMOD 62e-3
.MODEL RdrainMOD RES (TC1=6.6e-3 TC2=18e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.368137142857143 L=1.226e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=550e-10
+ XJ=0.62e-6
+ NCH=1.07e17
+ U0=900 VSAT=500000 DROUT=1.8
+ DELTA=0.25 PSCBE2=0 RSH=4.167e-3
+ VTH0=2.03
+ VOFF=-0.12 NFACTOR=1.4
+ LINT=0.141e-6 DLC=0.141e-6
+ CGSO=160e-12 CGSL=0 CGDO=0.5e-12 CGDL=190e-12
+ CJ=0 CF=0 CKAPPA=0.8
+ KT1=-1.2 KT2=0 UA1=5e-9
+ NJ=10)
.ENDS