.SUBCKT FDMC86102LZ 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC86102LZ Spice model                 **
**                      Revision RevA, 26 April 2011            **
******************************************************************		
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 1.735e-9		
Ldrain 2 5 0.005e-9		
Lsource 3 7 0.395e-9		
RLgate 1 9 17.35		
RLdrain 2 5 0.05		
RLsource 3 7 3.95		
Rgate 9 6 0.39		
* Shielded  Gate  		
D_D1 100 5 D_SG_cap1		
D_D2 100 101 D_SG_cap2		
R_R1 101 7 0.29		
C_C1 6 101 27e-12		
.MODEL D_SG_cap1 D (IS=1e-9 n=1 RS=5e-3 CJO=1.28e-9 M=0.6 t_abs=25)
.MODEL D_SG_cap2 D (IS=1e-9 n=1 RS=5e-3 CJO=0.9e-9 M=0.6 t_abs=25) 		
It 7 17 1		
Ebreak 11 7 17 7 109.4		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.73e-3 TC2=-1.0e-6)		
.MODEL DbodyMOD D (IS=4.4e-12 n=1 RS=6e-3 TRS1=2.5e-3 TRS2=1e-6 		
+ CJO=0.25e-9 M=0.39 TT=1e-9 XTI=2.5);0.74		
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 1.457e-3		
Rdrain 5 16 RdrainMOD 14.7e-3		
.MODEL RdrainMOD RES (TC1=6.7e-3 TC2=16e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=1.75 L=1.226e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=550e-10 ;Oxide thickness		
+ XJ=0.62e-6 ;Channel depth		
+ NCH=1.02e17 ;Channel concentration		
*Channel Current		
+ U0=910 VSAT=500000 DROUT=1.8		
+ DELTA=0.4 PSCBE2=0 RSH=1.457e-3		
*Threshold voltage		
+ VTH0=1.98		
*Sub-threshold characteristics		
+ VOFF=-0.24 NFACTOR=1		
*Junction diodes and Capacitance		
+ LINT=0.141e-6 DLC=0.141e-6 		
+ CGSO=62e-12 CGSL=0 CGDO=1.5e-12 CGDL=166e-12 ;77 		
+ CJ=0 CF=0 CKAPPA=0.25		
* Temperature parameters 		
+ KT1=-1.1 KT2=0 UA1=4.5e-9		
+ NJ=10)		
.ENDS