.SUBCKT FDMC86102 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
**      Scott Pearson   scott.pearson@fairchildsemi.com         **
**      Chris Hanas     chris.hanas@fairchildsemi.com           **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC86102 Spice model                   **
**                      Revision RevA, 4 Sep 2009               **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 1.625e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.245e-9
RLgate 1 9 16.25
RLdrain 2 5 0.04
RLsource 3 7 2.45
Rgate 9 6 1.06
It 7 17 1
Ebreak 11 7 17 7 110.7
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-0.6e-6)
.MODEL DbodyMOD D (IS=1.5e-12 n=1 RS=4e-3 TRS1=2.6e-3 TRS2=1e-6
+ CJO=0.75e-9 M=0.4 TT=10e-9 XTI=4)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 0.971e-3
Rdrain 5 16 RdrainMOD 14e-3
.MODEL RdrainMOD RES (TC1=7.3e-3 TC2=18e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=1.7 L=4.85e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1000e-10 ;Oxide thickness
+ XJ=0.62e-6 ;Channel depth
+ NCH=1.2e17 ;Channel concentration
*Channel Current
+ U0=850 VSAT=500000 DROUT=1.8
+ DELTA=0.13 PSCBE2=0.00001 RSH=0.971e-3
*Threshold voltage
+ VTH0=3.2
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=2.025e-6 DLC=2.025e-6
+ CGSO=167e-12 CGSL=0 CGDO=1e-12 CGDL=190e-12
+ CJ=0 CF=0 CKAPPA=1.0
* Temperature parameters
+ KT1=-1.8 KT2=0 UA1=0.75e-9
+ NJ=10)
.ENDS FDMC86102