*$
********************** Power MOSFET Electrical Parameters **********************
** Product: FDMC8321L
** N-Channel Power Trench MOSFET / 40V, 49A, 2.5mohm 
** Model Format: BSIM3V3
**----------------------------------------------------------------------------------------------
.SUBCKT FDMC8321L 2 1 3
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.517e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.084e-9
RLgate 1 9 5.17
RLdrain 2 5 0.04
RLsource 3 7 0.84
Rgate 9 6 1.49
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 4.58
C_C1 6 101 360e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.4e-9 M=0.6 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 44
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.65e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=4.2e-12 n=1 RS=1.58e-3 TRS1=4.9e-3 TRS2=1e-6 
+ CJO=3e-9 M=0.3 TT=3e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.489e-3
Rdrain 5 16 RdrainMOD 1.15e-3
.MODEL RdrainMOD RES (TC1=10e-3 TC2=20e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=5.76 L=0.624e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10
+ XJ=0.22e-6
+ NCH=1.4e17
+ U0=650 VSAT=500000 DROUT=1.2
+ DELTA=0.01 PSCBE2=0 RSH=0.489e-3
+ VTH0=1.8
+ VOFF=-0.1 NFACTOR=1.1
+ LINT=0.11e-6 DLC=0.11e-6 
+ CGSO=290e-12 CGSL=0 CGDO=5e-12 CGDL=150e-12 
+ CJ=0 CF=0 CKAPPA=0.52
+ KT1=-1.1 KT2=0 UA1=6e-9
+ NJ=10)
.ENDS   
*
**----------------------------------------------------------------------------------------------
** Creation: Mar.-28-2018   Rev: 2.0
** ON Semiconductor