.SUBCKT FDMC8296 2 1 3
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 1.375e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.243e-9
Rgate 9 6 0.9
It 7 17 1
Ebreak 11 7 17 7 35.5
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.8e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1e-12 n=1 RS=4.0e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=1.0e-9 M=0.3 TT=1e-9 XTI=3)
.MODEL DbreakMOD D (RS=70e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 0.99e-3
Rdrain 5 16 RdrainMOD 3.9e-3
.MODEL RdrainMOD RES (TC1=5.0e-3 TC2=9.5e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.016 L=0.81e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.58e-6 ;Channel depth
+ NCH=1.6e17 ;Channel concentration
*Channel Current
+ U0=750 VSAT=500000 DROUT=1.1
+ DELTA=0.081 PSCBE2=0.00001 RSH=1.05e-3
*Threshold voltage
+ VTH0=1.92
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.12e-6 DLC=0.12e-6
+ CGSO=100e-12 CGSL=0 CGDO=15e-12 CGDL=170.5e-12
+ CJ=0 CF=0 CKAPPA=2.2
* Temperature parameters
+ KT1=-1.0 KT2=0 UA1=2.4e-9
+ NJ=10)
* Rev A	SP	4/24/2008
.ENDS