.SUBCKT FDMC8032L 2 1 3
+params: tau=70 igain=40 fs=1400 
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                   FDMC8032L Spice model                      **
**                Revision RevA, 16 September 2013              **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD_trr
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.672e-9
Ldrain 2 5 0.006e-9
Lsource 3 7 0.169e-9
RLgate 1 9 6.72
RLdrain 2 5 0.06
RLsource 3 7 1.69
Rgate 9 6 1.2
H1   161 141 V_H1 {tau}
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 {-igain}
V_F1 171 141 0V
D1   151 161 DbodyMOD_trr
.MODEL DbodyMOD_trr D (IS=0.33e-12 n=1 RS=24.5e-3 TRS1=3.6e-3 TRS2=1e-6 
+ CJO=0.058e-9 M=0.348 TT=0 XTI=4)
R9   131 171  {tau*fs}
C2   161 131  1p
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 3.2
C_C1 6 101 60.4e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=0.45e-9 M=0.48 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 47.9
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.56e-3 TC2=-0.6e-6)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 1.57e-3
Rdrain 5 16 RdrainMOD 11.1e-3
.MODEL RdrainMOD RES (TC1=4e-3 TC2=7.5e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.941818181818182 L=0.624e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10 
+ XJ=0.22e-6 
+ NCH=1.4e17 
+ U0=670 VSAT=500000 DROUT=1.2
+ DELTA=0.17 PSCBE2=0 RSH=1.57e-3
+ VTH0=1.84
+ VOFF=-0.1 NFACTOR=1.3
+ LINT=0.11e-6 DLC=0.11e-6 
+ CGSO=256e-12 CGSL=0 CGDO=1e-12 CGDL=150e-12 
+ CJ=0 CF=0 CKAPPA=0.8
+ KT1=-1.1 KT2=0 UA1=4e-9
+ NJ=10)
.ENDS
*