.SUBCKT FDMC8010 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2011 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                   FDMC8010 Spice model (30V, 30A)            **
**                    Revision Rev-A, 14 Dec 2011               **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.517e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.071e-9
RLgate 1 9 5.17
RLdrain 2 5 0.05
RLsource 3 7 0.71
Rgate 9 6 1.01
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.58
C_C1 6 101 455e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=4.3e-9 M=0.45 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 32.7
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.56e-3 TC2=-0.4e-6)
.MODEL DbodyMOD D (IS=26.17e-12 n=1 RS=1e-3 TRS1=4e-3 TRS2=1e-6 
+ CJO=1.0e-9 M=0.35 TT=3e-9 XTI=5.75)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.102e-3
Rdrain 5 16 RdrainMOD 0.7e-3
.MODEL RdrainMOD RES (TC1=3.6e-3 TC2=15e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=11.3996 L=0.48e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10
+ XJ=0.195e-6
+ NCH=1.24e17
+ U0=670 VSAT=500000 DROUT=1.2
+ DELTA=0.3 PSCBE2=0 RSH=0.102e-3
+ VTH0=1.7
+ VOFF=-0.1 NFACTOR=0.9
+ LINT=0.09e-6 DLC=0.09e-6 
+ CGSO=160e-12 CGSL=0 CGDO=1e-12 CGDL=150e-12 
+ CJ=0 CF=0 CKAPPA=0.95
+ KT1=-1.025 KT2=0 UA1=3.1e-9
+ NJ=10)
.ENDS   
*