.SUBCKT FDMC7664 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
**      Scott Pearson   scott.pearson@fairchildsemi.com         **
**      Chris Hanas     chris.hanas@fairchildsemi.com           **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC7664 Spice model                    **
**                      Revision RevA, 09 Nov 2009              **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.517e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.056e-9
RLgate 1 9 5.17
RLdrain 2 5 0.05
RLsource 3 7 0.56
Rgate 9 6 0.82
* Shielded  Gate
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 1.94
C_C1 6 101 146e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=3.9e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 32.65
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.6e-3 TC2=-1.4e-6)
.MODEL DbodyMOD D (IS=3.3e-12 n=1 RS=3.1e-3 TRS1=2.4e-3 TRS2=2e-6
+ CJO=1.1e-9 M=0.44 TT=3e-9 XTI=4) ;3.2
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 0.367e-3
Rdrain 5 16 RdrainMOD 2.7e-3
.MODEL RdrainMOD RES (TC1=3.4e-3 TC2=3.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=8.036 L=2e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=2.2e17 ;Channel concentration
*Channel Current
+ U0=850 VSAT=500000 DROUT=1.2
+ DELTA=0.1 PSCBE2=0.00001 RSH=0.367e-3
*Threshold voltage
+ VTH0=1.42
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.71e-6 DLC=0.71e-6
+ CGSO=50e-12 CGSL=0 CGDO=0.3e-12 CGDL=113e-12 ;67
+ CJ=0 CF=0 CKAPPA=2.6
* Temperature parameters
+ KT1=-1.15 KT2=0 UA1=0.03e-9
+ NJ=10)
.ENDS FDMC7664