.SUBCKT FDMC7208S_Q1 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group       	            **
******************************************************************
**      Website www.fairchildsemi.com                           **
******************************************************************
**      (C) Copyright 2012 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMC7208S Spice model                   **
**                    Revision RevA, 8 August 2012              **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.036e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.472e-9
RLgate 1 9 20.36
RLdrain 2 5 0.04
RLsource 3 7 4.72
Rgate 9 6 1.78 
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 4.3
C_C1 6 101 96e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=0.78e-9 M=0.51 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 32
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.85e-3 TC2=-1.3e-6)
.MODEL DbodyMOD D (IS=2.5e-12 n=1 RS=6e-3 TRS1=3.5e-3 TRS2=1e-6 
+ CJO=0.2e-9 M=0.35 TT=3e-9 XTI=7)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.489e-3
Rdrain 5 16 RdrainMOD 5.45e-3
.MODEL RdrainMOD RES (TC1=3.2e-3 TC2=8.25e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.04 L=0.48e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10 
+ XJ=0.195e-6 
+ NCH=1.24e17 
+ U0=670 VSAT=500000 DROUT=1.2
+ DELTA=0.27 PSCBE2=0 RSH=0.489e-3
+ VTH0=1.94
+ VOFF=-0.1 NFACTOR=1.25
+ LINT=0.09e-6 DLC=0.09e-6 
+ CGSO=192e-12 CGSL=0 CGDO=6e-12 CGDL=138e-12 
+ CJ=0 CF=0 CKAPPA=0.95 
+ KT1=-1 KT2=0 UA1=1.1e-9
+ NJ=10)
.ENDS FDMC7208S_Q1
*
.SUBCKT FDMC7208S_Q2 2 1 3
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dschottky 7 5 DSchottkyMOD  
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.578e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.124e-9
RLgate 1 9 5.78
RLdrain 2 5 0.04
RLsource 3 7 1.24
Rgate 9 6 1.71
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 4.3
C_C1 6 101 140e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.45e-9 M=0.57 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-1e-6) ; TC1=0.7e-3 TC2=-1e-6
.MODEL DbodyMOD D (IS=1.0e-12 n=1 RS=3.5e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.19e-9 M=0.39 TT=3e-9 XTI=0.2)
.MODEL DSchottkyMOD D (IS=1.0e-6 n=1 RS=170e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.19e-9 M=0.39 TT=3e-9 XTI=-19)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 ) ; RS=30e-3 TRS1=1e-3 TRS2=1e-6
Rsource 7a 7 0.489e-3
Rdrain 5 16 RdrainMOD 3.8e-3
.MODEL RdrainMOD RES (TC1=3.2e-3 TC2=6.3e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.98 L=0.47e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=300e-10 
+ XJ=0.2e-6 
+ NCH=2.8e17 
+ U0=670 VSAT=500000 DROUT=1.2
+ DELTA=0.3 PSCBE2=0 RSH=0.489e-3
+ VTH0=0.375
+ VOFF=-0.1 NFACTOR=1.2
+ LINT=0.09e-6 DLC=0.09e-6 
+ CGSO=200e-12 CGSL=0 CGDO=2e-12 CGDL=178e-12 
+ CJ=0 CF=0 CKAPPA=0.6
+ KT1=-0.77 KT2=0 UA1=6e-9
+ NJ=10)
.ENDS FDMC7208S_Q2
*