* PSpice Model Editor - Version 10.5.0
*$
*FDMC6890NZ Electrical Model(N-Channel_Q1)
*----------------------------------------------------
.SUBCKT FDMC6890NZ_Q1 2 1 3  
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 22
Lgate 1 9 0.96e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.36e-9
RLgate 1 9 9.6
RLdrain 2 5 1
RLsource 3 7 3.6
Rgate 9 6 3.3
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=8.73e-11 n=1.15 RS=4E-2 TRS1=5e-6 TRS2=8e-6 
+ CJO=1.1e-10 M=0.32 TT=17n XTI=-5)
.MODEL DbreakMOD D (RS=1.8e-1 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 35m
.MODEL RdrainMOD RES (TC1=4e-3 TC2=7e-6)
M_BSIM3 16 6 7 7 Bsim3 W=0.26 L=1.1u NRS=1
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=3 paramchk=1 NQSMOD=0
**Process Parameters
+ TOX=240e-10 ;Oxide thickness
+ XJ=0.2u ;Channel depth
+ NCH=1.2e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=1e5 DROUT=2
+ DELTA=0.1 PSCBE2=0 RSH=6.4m   
**Threshold voltage
+ VTH0=1.05
**Sub-threshold characteristics
+ VOFF=-0.05 NFACTOR=3.5
**Junction diodes and Capacitance
+ LINT=0.25u DLC=0.25u 
+ CGSO=190p CGSL=0 CGDO=110p CGDL=410p
+ CJ=0 CF=0 CKAPPA=0.65 
** Temperature parameters
+ KT1=-1 KT2=0 UA1=1.6e-8 
+ NJ=10
.ENDS

*$
*---------------------------------------------------
*FDMC6890NZ Electrical Model(N-Channel_Q2)
*---------------------------------------------------
.SUBCKT FDMC6890NZ_Q2 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 22
Lgate 1 9 0.84e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.246e-9
RLgate 1 9 8.4
RLdrain 2 5 1
RLsource 3 7 2.46
Rgate 9 6 2.8
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=2e-10 n=1.13 RS=3.9e-2 TRS1=5e-8 TRS2=6e-8 
+ CJO=9.8e-11 M=0.28 TT=6n XTI=1)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 37m
.MODEL RdrainMOD RES (TC1=4e-3 TC2=2e-6)
M_BSIM3 16 6 7 7 Bsim3 W=0.176 L=1.34u NRS=1
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
**Process Parameters
+ TOX=300e-10 ;Oxide thickness
+ XJ=0.94u ;Channel depth
+ NCH=1.7e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1
+ DELTA=0.01 PSCBE2=0 RSH=4.4m   
**Threshold voltage
+ VTH0=0.9
**Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=3.2
**Junction diodes and Capacitance
+ LINT=0.37u DLC=0.37u 
+ CGSO=280p CGSL=0 CGDO=130p CGDL=520p
+ CJ=0 CF=0 CKAPPA=1.5
** Temperature parameters
+ KT1=-0.75 KT2=0 UA1=0.3e-8 
+ NJ=10
.ENDS
*FDMC6890NZ (Rev.A) 10/4/06
*ST
*$