.SUBCKT FDMC610P 2 1 3
+params: tau=10 igain=10 fs=1000
******************************************************************
**      Fairchild Discrete Modeling Group					    **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                   FDMC610P PSpice model                  	**
**              Revision RevA, 29 November 2013       		    **
******************************************************************
*Nom Temp 25 deg C
Dbreak 7 11 DbreakMOD 
Lgate 1 9 0.517e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.112e-9
RLgate 1 9 5.17
RLdrain 2 5 0.05
RLsource 3 7 1.12
Rgate 9 6 4.03
H1   161 141 V_H1 {tau}
V_H1 151 5 0V
V10  7 161 0
F1   5 161 V_F1 {-igain}
V_F1 171 141 0V
D3   151 161 Dbody_trr
.MODEL Dbody_trr D (IS=200e-12 n=1 RS=4e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.15e-9 M=0.23 TT=0 XTI=-3)
R9   131 171  {tau*fs}
C2   161 131  1p  
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 9.16
C_C1 6 101 960e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=0.58e-9 M=0.38 t_abs=25) 
It 7 17 1
Ebreak 5 11 17 7 -20
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.8e-3 TC2=-1e-6)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.154e-3
Rdrain 5 16 RdrainMOD 2.25e-3
.MODEL RdrainMOD RES (TC1=1.8e-3 TC2=0.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=8.25 L=0.59e-6 NRS=0 NRD=0
.MODEL Bsim3 PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=160e-10 
+ XJ=0.15e-6 
+ NCH=1.6e17 
+ U0=250 VSAT=500000 DROUT=1.8
+ DELTA=0.4 PSCBE2=0 RSH=0.154e-3
+ VTH0=-0.845
+ VOFF=-0.13 NFACTOR=1.4
+ LINT=0.17e-6 DLC=0.17e-6 
+ CGSO=464e-12 CGSL=0 CGDO=120e-12 CGDL=240e-12 
+ CJ=0 CF=0 CKAPPA=1
+ KT1=-0.55 KT2=0 UA1=8e-9
+ NJ=10)
.ENDS
*