.SUBCKT FDMC3020DC 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       		       **
******************************************************************
**      Website         www.fairchildsemi.com\models                                             **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation                          **
**                      All rights reserved                     		             	       **
**                                                                                                                            **
**                      FDMS3020DC Spice model                   	         	       **
**                    Revision RevA, 29 July 2010                		       **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.765e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.321e-9
RLgate 1 9 7.65
RLdrain 2 5 0.04
RLsource 3 7 3.21
Rgate 9 6 1.36
It 7 17 1
Ebreak 11 7 17 7 35.45
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.61e-3 TC2=-0.75e-6)
.MODEL DbodyMOD D (IS=5.0e-12 n=1.055 RS=1.7e-3 TRS1=2.5e-3 TRS2=5e-6 
+ CJO=0.75e-9 M=0.28 TT=0.1e-9 XTI=4.0)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.26e-3
Rdrain 5 16 RdrainMOD 3.2e-3
.MODEL RdrainMOD RES (TC1=4.5e-3 TC2=12.0e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.016 L=2.15e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.58e-6 ;Channel depth
+ NCH=1.6e17 ;Channel concentration
*Channel Current
+ U0=680 VSAT=500000 DROUT=1.1
+ DELTA=0.06 PSCBE2=0.00001 RSH=0.26e-3
*Threshold voltage
+ VTH0=1.8
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.79e-6 DLC=0.79e-6 
+ CGSO=107e-12 CGSL=0 CGDO=15.5e-12 CGDL=159e-12
+ CJ=0 CF=0 CKAPPA=1.5
* Temperature parameters 
+ KT1=-1.1 KT2=0 UA1=3.5e-9
+ NJ=10)
.ENDS