.SUBCKT FDMC2610 2 1 3  
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 220
Lgate 1 9 1.74e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.084e-9
RLgate 1 9 17.4
RLdrain 2 5 1
RLsource 3 7 0.84
Rgate 9 6 0.7
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1.15e-12 n=1 RS=1.1E-2 TRS1=1e-3 TRS2=1e-5 
+ CJO=4.7e-10 M=0.5 TT=134n XTI=2.5)
.MODEL DbreakMOD D (RS=1.8e-1 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 167m
.MODEL RdrainMOD RES (TC1=8e-3 TC2=2e-5)
M_BSIM3 16 6 7 7 Bsim3 W=1.4 L=1.47u NRS=1 NRD=0
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=3 paramchk=1 NQSMOD=0
**Process Parameters
+ TOX=1250e-10 ;Oxide thickness
+ XJ=1.7u ;Channel depth
+ NCH=1.7e17 ;Channel concentration
**Channel Current
+ U0=1900 VSAT=5e5 DROUT=1.5
+ DELTA=0.2 PSCBE2=0 RSH=3.08m   
**Threshold voltage
+ VTH0=3.1
**Sub-threshold characteristics
+ VOFF=-0.25 NFACTOR=1
**Junction diodes and Capacitance
+ LINT=0.12u DLC=0.12u 
+ CGSO=120p CGSL=0 CGDO=8p CGDL=120p
+ CJ=0 CF=0 CKAPPA=0.9 
** Temperature parameters
+ KT1=-1.4 KT2=0 UA1=1.5e-10 
+ NJ=10)
.ENDS
*FDMC2610(Rev.A1) 7/18/08
*ST
*$


.SUBCKT FDMC2610_JA tj ta 
*Thermal Model Subcircuit  02/13/2017
*min pad area junction to ambient model
*Foster thermal model
CTHERM1 tj 6 1E-003
CTHERM2 6 5  0.007319
CTHERM3 5 4  0.0282
CTHERM4 4 3  0.0927
CTHERM5 3 2  0.5914
CTHERM6 2 ta 7.196
RTHERM1 tj 6 0.3043
RTHERM2 6 5  0.9342
RTHERM3 5 4  4.026
RTHERM4 4 3  12.96
RTHERM5 3 2  22.47
RTHERM6 2 ta 19.19
.ends FDMC2610_JA