**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDMC2523P 
** 150V P-Channel MOSFET and Power 33
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.subckt FDMC2523P  2 1 3
*Nom Temp=25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Lgate 1 9 1.1e-9
Ldrain 2 5 0.5e-9
Lsource 3 7 0.5e-9
RLgate 1 9 11
RLdrain 2 5 5
RLsource 3 7 5
Rgate 9 6 0.5
It 7 17 1
Ebreak 5 11 17 7 -150
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=9.8e-4 TC2=-1.4e-6)
.MODEL DbodyMOD D (IS=4.1e-13  N=1.0    RS=0.402    TRS1=1.0e-4  TRS2=1.5e-6
+ CJO=2.95e-10     M=0.44      VJ=0.45  TT=1.38e-7  XTI=3        EG=1.16)
.MODEL DbreakMOD D (RS=0.1 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 0.8
.MODEL RdrainMOD RES (TC1=7.5e-3 TC2=1.04e-7)
M_BSIM3 16 6 7 7 Bsim3 W=0.65 L=2.0e-6 NRS=1
.MODEL Bsim3 PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1000e-10     XJ=1.0e-6       NCH=1.3e17
+ U0=250           VSAT=5e5        DROUT=1.0
+ DELTA=0.1        PSCBE2=0        RSH=1.5e-3
+ VTH0=-3.90       VOFF=-0.1       NFACTOR=1.1     
+ LINT=1.7e-7      DLC=1.7e-7      CGSO=2.95e-11
+ CGSL=0           CGDO=2.06e-13   CGDL=2.75e-10
+ CJ=0             CF=0            CKAPPA=0.2
+ KT1=-1.55        KT2=0           UA1=-1.05e-9
+ NJ=10            FC=0.5)
.ends

******************** Power Discrete MOSFET Thermal Model ************************
** 150V P-Channel MOSFET and Power 33
**-------------------------------------------------------------------------------
.SUBCKT FDMC2523P_Thermal TH TL
CTHERM1 TH 6 1.64e-2
CTHERM2 6 5  8.08e-2
CTHERM3 5 4  8.64e-1
CTHERM4 4 3  1.82e-0
CTHERM5 3 2  8.82e-0
CTHERM6 2 TL 9.32e-0
RTHERM1 TH 6 1.31e-2
RTHERM2 6 5  5.64e-2
RTHERM3 5 4  2.57e-1
RTHERM4 4 3  3.21e-1
RTHERM5 3 2  7.53e-1
RTHERM6 2 TL 1.60e+0
.ENDS FDMC2523P_Thermal 
**-------------------------------------------------------------------------------
** Creation: Dec.-23-2010   Rev.: 0.0
** Fairchild Semiconductor