* OrCAD Model Editor - Version 9.1
*$
.SUBCKT FDMB668P 2 1 3   
*Nom Temp=25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Ebreak 5 11 17 7 -22
Lgate 1 9 0.627e-9
Ldrain 2 5 1e-9 
Lsource 3 7 0.197e-9
RLgate 1 9 6.27
RLdrain 2 5 10
RLsource 3 7 1.97
Rgate 9 6 18
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=6e-4 TC2=-2e-7)
.MODEL DbodyMOD D (IS=1.86e-9 n=1.05 RS=2.3e-2 TRS1=5e-5 TRS2=8e-6
+ CJO=5e-10 M=0.65 TT=15n XTI=-8)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 15.5m 
.MODEL RdrainMOD RES (TC1=4e-3 TC2=1e-5)
M_BSIM3 16 6 7 7 M_MOD W=1.72 L=0.89u NRS=1  
.MODEL  M_MOD PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
***Process Parameters
+ TOX=160e-10 ;Oxide thickness
+ XJ=0.3u ;Channel depth 
+ NCH=1.95e17 ;Channel concentration
***Channel Current
+ U0=200 vsat=5e5 drout=1 
+ DELTA=0.25 PSCBE2=0 RSH=2.8m 
***Threshold voltage
+ VTH0=-0.65
***Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.4 
***Junction diodes and Capacitance
+ LINT=0.215u DLC=0.215u 
+ CGSO=250p CGSL=0p CGDO=50p CGDL=780p 
+ CJ=0 CF=0p CKAPPA=0.45
*** Temperature parameters
+ KT1=-0.45 KT2=0 UA1=2.2E-9
+ NJ=10 
.ENDS 
*FDMB668P(Rev.A) 2/9/07
*ST
*$