* PSpice Model Editor - Version 16.3.0
*$
.SUBCKT FDMB2307NZ 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMB2307NZ Spice model                  **
**                      Revision RevA, 20 October 2011          **
******************************************************************			
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 0.449e-9		
Ldrain 2 5 0.008e-9		
Lsource 3 7 0.468e-9		
RLgate 1 9 4.49		
RLdrain 2 5 0.08		
RLsource 3 7 4.68		
Rgate 9 6 3.28
* Shielded  Gate  		
D_D1 100 5 D_SG_cap1		
D_D2 100 101 D_SG_cap2		
R_R1 101 7 0.87		
C_C1 6 101 100e-12		
.MODEL D_SG_cap1 D (IS=1e-9 n=1 RS=5e-3 CJO=0.23e-9 M=0.6 t_abs=25)
.MODEL D_SG_cap2 D (IS=1e-9 n=1 RS=5e-3 CJO=0.01e-9 M=0.6 t_abs=25)
It 7 17 1		
Ebreak 11 7 17 7 24.1		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-2e-6)		
.MODEL DbodyMOD D (IS=30e-12 n=1 RS=8e-3 TRS1=1e-3 TRS2=1e-6 		
+ CJO=0.018e-9 M=0.35 TT=3e-9 XTI=-3);0.054		
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 2.415e-3		
Rdrain 5 16 RdrainMOD 3.65e-3		
.MODEL RdrainMOD RES (TC1=5.4e-3 TC2=4e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=2.46 L=0.76e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=240e-10 ;Oxide thickness		
+ XJ=0.15e-6 ;Channel depth		
+ NCH=2.1e17 ;Channel concentration		
*Channel Current		
+ U0=1200 VSAT=50000 DROUT=1.2		
+ DELTA=0.3 PSCBE2=0 RSH=2.415e-3		
*Threshold voltage		
+ VTH0=0.61		
*Sub-threshold characteristics		
+ VOFF=-0.055 NFACTOR=1.15		
*Junction diodes and Capacitance		
+ LINT=0.215e-6 DLC=0.215e-6 		
+ CGSO=162e-12 CGSL=0 CGDO=35e-12 CGDL=415e-12 ;203		
+ CJ=0 CF=0 CKAPPA=1.5		
* Temperature parameters 		
+ KT1=-0.49 KT2=0 UA1=1e-9		
+ NJ=10)		
.ENDS   		
* 		
*$