.SUBCKT FDMA86551L 2 1 3
+params: tau=50 igain=85 fs=550
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMA86551L Spice model                 	**
**                    Revision RevA, 25 October 2013            **
******************************************************************
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.456e-9
Ldrain 2 5 0.007e-9
Lsource 3 7 0.106e-9
RLgate 1 9 4.56
RLdrain 2 5 0.07
RLsource 3 7 1.06
Rgate 9 6 0.85
H1   161 141 V_H1 {tau}
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 {-igain}
V_F1 171 141 0V
D3   151 161 Dbody_trr
.MODEL Dbody_trr D (IS=3e-11 n=1.1 RS=8.6e-3 TRS1=0.9e-3 TRS2=1e-6
+ CJO=2e-10 M=0.62 TT=0 XTI=0.1)
R9   131 171  {tau*fs}
C2   161 131  1p
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.48
C_C1 6 101 250e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=0.67e-9 M=0.4 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 66
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.6e-3 TC2=-1e-6)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 2.662e-3
Rdrain 5 16 RdrainMOD 14.409e-3
.MODEL RdrainMOD RES (TC1=4.3e-3 TC2=9e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.96 L=0.88e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10
+ XJ=0.3e-6
+ NCH=2.3e17
+ U0=750 VSAT=500000 DROUT=1.2
+ DELTA=0.12 PSCBE2=0 RSH=2.662e-3
+ VTH0=1.1
+ VOFF=-0.1 NFACTOR=1.1
+ LINT=0.11e-6 DLC=0.11e-6
+ CGSO=220e-12 CGSL=0 CGDO=5e-12 CGDL=250e-12
+ CJ=0 CF=0 CKAPPA=0.5
+ KT1=-1.1 KT2=0 UA1=3e-9
+ NJ=10)
.ENDS FDMA86551L