.SUBCKT FDMA7632 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMA7632 Spice model                    **
**                      Revision RevA, 13 August 2010           **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.565e-9
Ldrain 2 5 0.007e-9
Lsource 3 7 0.326e-9
RLgate 1 9 5.65
RLdrain 2 5 0.07
RLsource 3 7 3.26
Rgate 9 6 2.99
* Shielded  Gate
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 8.55
C_C1 6 101 25e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=8.6e-3 CJO=0.7e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 32.3
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.65e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=0.45e-12 n=1 RS=10e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=0.13e-9 M=0.32 TT=3e-9 XTI=2);0.39
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 2.731e-3
Rdrain 5 16 RdrainMOD 9.6e-3
.MODEL RdrainMOD RES (TC1=3.4e-3 TC2=4.4e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=1.36 L=1.7e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=1.57e17 ;Channel concentration
*Channel Current
+ U0=880 VSAT=500000 DROUT=1.2
+ DELTA=0.25 PSCBE2=0.00001 RSH=2.731e-3
*Threshold voltage
+ VTH0=2.22
*Sub-threshold characteristics
+ VOFF=-0.2 NFACTOR=2.1
*Junction diodes and Capacitance
+ LINT=0.585e-6 DLC=0.585e-6
+ CGSO=70e-12 CGSL=10e-12 CGDO=9e-12 CGDL=185e-12 ;88
+ CJ=0 CF=0 CKAPPA=0.25
* Temperature parameters
+ KT1=-1.3 KT2=0 UA1=3e-9
+ NJ=10)
.ENDS