* OrCAD Model Editor - Version 9.1
*$
.SUBCKT FDMA530PZ 2 1 3   
*Nom Temp=25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Ebreak 5 11 17 7 -33
Lgate 1 9 0.55e-9
Ldrain 2 5 1e-9 
Lsource 3 7 0.164e-9
RLgate 1 9 5.5
RLdrain 2 5 10
RLsource 3 7 1.64
Rgate 9 6 10.92
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=3.8e-13 n=1 RS=1.8e-2 TRS1=7e-7 TRS2=1e-5
+ CJO=2.1e-10 M=0.5 TT=1e-10 XTI=2.5)
.MODEL DbreakMOD D (RS=9e-2 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 23e-3 
.MODEL RdrainMOD RES (TC1=4e-3 TC2=5e-6)
M_BSIM3 16 6 7 7 M_MOD W=1.67 L=0.92e-6 NRS=1 NRD=0  
.MODEL  M_MOD PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
***Process Parameters
+ TOX=550e-10 ;Oxide thickness
+ XJ=0.3e-6 ;Channel depth 
+ NCH=1.36e17 ;Channel concentration
***Channel Current
+ U0=250 vsat=5e5 drout=1 
+ DELTA=0.4 PSCBE2=1e-5 RSH=2.4e-3 
***Threshold voltage
+ VTH0=-2.1
***Sub-threshold characteristics
+ VOFF=-0.16 NFACTOR=1 
***Junction diodes and Capacitance
+ LINT=0.21e-6 DLC=0.21e-6 
+ CGSO=120e-12 CGSL=0 CGDO=80e-12 CGDL=240e-12 
+ CJ=0 CF=0p CKAPPA=1.5 
*** Temperature parameters
+ KT1=-1.2 KT2=0 UA1=1.7E-9
+ NJ=10) 
.ENDS 
*FDMA530PZ(Rev.B) 6/12/2007
*ST
*$