* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMA410NZ 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.582e-9
Ldrain 2 5 0.007e-9
Lsource 3 7 0.296e-9
RLgate 1 9 5.82
RLdrain 2 5 0.07
RLsource 3 7 2.96
Rgate 9 6 2.1
It 7 17 1
Ebreak 11 7 17 7 22
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.85e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=8.7e-11 n=1 RS=6.05e-3 TRS1=3e-3 TRS2=1e-6
+ CJO=0.219e-9 M=0.5 TT=0.1e-9 XTI=-2)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=0)
Rsource 7a 7 5.078e-3
Rdrain 5 16 RdrainMOD 9.5e-3
.MODEL RdrainMOD RES (TC1=6.5e-3 TC2=1e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.922 L=0.93e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS(LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=160e-10 ;Oxide thickness
+ XJ=0.42e-6 ;Channel depth
+ NCH=1.8e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1.2
+ DELTA=0.1 PSCBE2=1e-5 RSH=5.078e-3  
**Threshold voltage
+ VTH0=0.7
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.145e-6 DLC=0.145e-6 
+ CGSO=92e-12 CGSL=0e-12 CGDO=56e-12 CGDL=408e-12
+ CJ=0 CF=0 CKAPPA=0.45
** Temperature parameters
+ KT1=-0.55 KT2=0 UA1=4.8e-9
+ NJ=10)
.ENDS
*FDMA410NZ(Rev.A) 10/23/2008
*ST
*$