* OrCAD Model Editor - Version 9.1
*$
.SUBCKT FDMA3023PZ 2 1 3   
*Nom Temp=25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Ebreak 5 11 17 7 -33
Lgate 1 9 0.657e-9
Ldrain 2 5 0.011e-9 
Lsource 3 7 0.177e-9
RLgate 1 9 6.57
RLdrain 2 5 0.11
RLsource 3 7 1.77
Rgate 9 6 11.9
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES(TC1=0.8e-3 TC2=-0.5e-6)
.MODEL DbodyMOD D(IS=1.51e-10 n=1 RS=3.12e-1 TRS1=5e-3 TRS2=1e-6
+ CJO=0.195e-9 M=0.4 TT=11.17n XTI=-6)
.MODEL DbreakMOD D(RS=80e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 5.19e-3
Rdrain 5 16 RdrainMOD 62e-3 
.MODEL RdrainMOD RES (TC1=3.5e-3 TC2=4e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.64 L=1.06e-6 NRS=0 
.MODEL Bsim3 PMOS(LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=160e-10 ;Oxide thickness
+ XJ=0.5e-6 ;Channel depth 
+ NCH=1.86e17 ;Channel concentration
**Channel Current
+ U0=225 vsat=5e5 drout=1.5 
+ DELTA=0.1 PSCBE2=0.00001 RSH=5.19e-3
**Threshold voltage
+ VTH0=-0.7
***Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1
**Junction diodes and Capacitance
+ LINT=0.195e-6 DLC=0.195e-6 
+ CGSO=50e-12 CGSL=0e-12 CGDO=65e-12 CGDL=395e-12 
+ CJ=0 CF=0p CKAPPA=1
**Temperature parameters
+ KT1=-0.65 KT2=0 UA1=6e-9
+ NJ=10 
.ENDS 
*FDMA3023PZ(Rev.A) 12/19/08
*ST
*$