* PSpice Model Editor - Version 10.5.0
*$
*FDMA1032CZ Electrical Model(Complementary N-Channel)
*----------------------------------------------------
.SUBCKT FDMA1032CZ_Q1 2 1 3   
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 25
Lgate 1 9 0.45e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.19e-9
RLgate 1 9 4.5
RLdrain 2 5 1
RLsource 3 7 1.9
Rgate 9 6 2.1
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=2.6e-11 n=1.1 RS=1.6e-2 TRS1=1.4e-4 TRS2=0 
+ CJO=1.2e-10 M=0.35 TT=5n XTI=0.5)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 28m
.MODEL RdrainMOD RES (TC1=8e-4 TC2=1e-6)
M_BSIM3 16 6 7 7 Bsim3 W=0.43 L=1.1u NRS=1
.MODEL  Bsim3 NMOS ( LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
**Process Parameters
+ TOX=240e-10 ;Oxide thickness
+ XJ=0.52u ;Channel depth
+ NCH=1.2e17 ;Channel concentration
**Channel Current
+ U0=500 VSAT=5e6 DROUT=1.5
+ DELTA=0.5 PSCBE2=0 RSH=0.3m   
**Threshold voltage
+ VTH0=1.15
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.2
**Junction diodes and Capacitance
+ LINT=0.25u DLC=0.25u 
+ CGSO=170p CGSL=0 CGDO=70p CGDL=420p
+ CJ=0 CF=0 CKAPPA=1
** Temperature parameters
+ KT1=-1 KT2=0 UA1=1e-8 
+ NJ=10
.ENDS
*$
*---------------------------------------------------
*FDMA1032CZ Electrical Model(Complementary P-Channel)
*---------------------------------------------------
.SUBCKT FDMA1032CZ_Q2 2 1 3   
*Nom Temp=25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Ebreak 5 11 17 7 -25
Lgate 1 9 0.56e-9
Ldrain 2 5 0.1e-9 
Lsource 3 7 0.23e-9
RLgate 1 9 5.6
RLdrain 2 5 1
RLsource 3 7 2.3
Rgate 9 6 11.5
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=7e-4 TC2=-2e-7)
.MODEL DbodyMOD D (IS=1.55e-10 n=1.16 RS=9.2e-2 TRS1=2.5e-8 TRS2=5.5e-6
+ CJO=1.4e-10 M=0.55 TT=15.5n XTI=0.5 IKF=0.1)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 32m 
.MODEL RdrainMOD RES (TC1=5.5e-3 TC2=1e-5)
M_BSIM3 16 6 7 7 M_MOD W=0.6404 L=1.03u NRS=1  
.MODEL  M_MOD PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=240e-10 ;Oxide thickness
+ XJ=0.31u ;Channel depth 
+ NCH=1.75e17 ;Channel concentration
**Channel Current
+ U0=250 vsat=5e5 drout=0.5 
+ DELTA=0.5 PSCBE2=0 RSH=13.7m 
**Threshold voltage
+ VTH0=-0.93
**Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.4 
**Junction diodes and Capacitance
+ LINT=0.285u DLC=0.285u 
+ CGSO=250p CGSL=0p CGDO=75p CGDL=800p 
+ CJ=0 CF=0p CKAPPA=0.55 
**Temperature parameters
+ KT1=-0.58 KT2=0 UA1=1.5E-11 
+ NJ=10 
.ENDS 
*FDMA1032CZ(Rev.A) 5/12/06
*ST
*$