*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDL100N50F 
** N-Channel UniFET FRFET MOSFET
** 500V 100A 55mohm
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDL100N50F 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 550
Lgate 1 9    1.18e-9
Ldrain 2 5   1.440e-9
Lsource 3 7  9.88e-10
RLgate 1 9   10
RLdrain 2 5  10
RLsource 3 7 10
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.35e-3 TC2=-1.32e-6)
.MODEL DbodyMOD D (IS=9.25e-11  N=1.0       RS=0.27e-2  TRS1=2.6e-3  TRS2=1.15e-6 
+ CJO=2.12e-8  M=0.64  VJ=0.46  TT=2.45e-7  XTI=0.3     EG=1.16)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 0.0424
.MODEL RdrainMOD RES (TC1=7.9e-3 TC2=3.65e-5)
M_BSIM3 16 6 7 7 BSIM3 W=30.0 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10     XJ=1.4e-6      NCH=1.85e17
+ U0=700           VSAT=1.0e5     DROUT=1.0
+ DELTA=0.10       PSCBE2=0       RSH=1.03e-5
+ VTH0=4.45        VOFF=-0.1      NFACTOR=1.1
+ LINT=3.22e-7     DLC=3.22e-7    FC=0.5
+ CGSO=1.0e-15     CGSL=0         CGDO=1.0e-15  
+ CGDL=3.64e-10    CJ=0           CF=0 
+ CKAPPA=0.01      KT1=-1.48      KT2=0
+ UA1=-2.59e-9     NJ=10)
.ENDS
*$
******************** Power Discrete MOSFET Thermal Model ************************
** 500V N-Channel MOSFET and TO-264
**-------------------------------------------------------------------------------
.SUBCKT FDL100N50F_Thermal TH TL
CTHERM1 TH 6 6.44e-2
CTHERM2 6 5  8.88e-2
CTHERM3 5 4  9.74e-2
CTHERM4 4 3  1.42e-1
CTHERM5 3 2  3.65e-1
CTHERM6 2 TL 4.02e-1
RTHERM1 TH 6 2.00e-4
RTHERM2 6 5  6.90e-4
RTHERM3 5 4  4.20e-3
RTHERM4 4 3  7.70e-3
RTHERM5 3 2  9.70e-3
RTHERM6 2 TL 2.80e-2
.ENDS FDL100N50F_Thermal 
**-------------------------------------------------------------------------------
** Creation: Mar.-21-2019   Rev.: 1.0
** ON Semiconductor