* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDI8441 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 3.6e-9
Ldrain 2 5 1.0e-9
Lsource 3 7 0.56e-9
RLgate 1 9 36
RLdrain 2 5 10
RLsource 3 7 5.6
Rgate 9 6 1.1
It 7 17 1
Ebreak 11 7 17 7 44
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=9.5e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1.06e-11 n=1.07 RS=1.4e-3 TRS1=2.5e-3 TRS2=1e-6 
+ CJO=2.3e-9 M=0.38 TT=30n XTI=3)
.MODEL DbreakMOD D (RS=1e-1 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 1.7e-3
.MODEL RdrainMOD RES (TC1=8e-3 TC2=1.5e-5)
M_BSIM3 16 6 7 7 Bsim3 W=24.01 L=1.03e-6 NRS=1 NRD=0
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.2 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.48e-6 ;Channel depth
+ NCH=3.05e17 ;Channel concentration
**Channel Current
+ U0=3500 VSAT=5e4 DROUT=0.5
+ DELTA=0.2 PSCBE2=1e-5 RSH=0.2e-3
**Threshold voltage
+ VTH0=2.4
**Sub-threshold characteristics
+ VOFF=-0.3 NFACTOR=1
**Junction diodes and Capacitance
+ LINT=0.12e-6 DLC=0.12e-6 
+ CGSO=30e-12 CGSL=0 CGDO=10e-12 CGDL=210e-12
+ CJ=0 CF=0 CKAPPA=0.7 ACDE=1 MOIN=15 
** Temperature parameters
+ KT1=-1.5 KT2=0 UA1=1e-8 
+ NJ=10)
.ENDS
*FDI8441(Rev.A) 6/22/07
*ST
*$