.SUBCKT fdi040n06 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDI040N06 Spice model                **
**                      Revision RevA, 20 MARCH 2010               **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 5.128e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 2.352e-9
RLgate 1 9 51.28
RLdrain 2 5 1
RLsource 3 7 23.52
Rgate 9 6 0.74
It 7 17 1
Ebreak 11 7 17 7 66
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=1.25e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=40.67e-12 n=1.06 RS=1.3e-3 TRS1=2.2e-3 TRS2=1e-6 
+ CJO=2.644e-9 M=0.45 TT=0.1e-9 XTI=2.6)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.47e-3
Rdrain 5 16 RdrainMOD 2.25e-3
.MODEL RdrainMOD RES (TC1=5.8e-3 TC2=16e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=13.468 L=1.58e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1050e-10 ;Oxide thickness
+ XJ=0.89e-6 ;Channel depth
+ NCH=1.25e17 ;Channel concentration
*Channel Current
+ U0=1300 VSAT=800000 DROUT=1.8
+ DELTA=0.32 PSCBE2=0.00001 RSH=0.436e-3
*Threshold voltage
+ VTH0=4.15
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.28e-6 DLC=0.28e-6 
+ CGSO=103e-12 CGSL=-6e-12 CGDO=7.9e-12 CGDL=-7.9e-12 
+ CJ=0 CF=0 CKAPPA=1.5
* Temperature parameters 
+ KT1=-2.22 KT2=0 UA1=1e-9
+ NJ=10)
.ENDS   
* Rev.0_SB
* Rev0 model