.SUBCKT FDI025N06 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
**      Scott Pearson   scott.pearson@fairchildsemi.com         **
**      Sylvie Tran     sylvie.tran@fairchildsemi.com           **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDI025N06 Spice model                   **
**                      Revision RevA, 15 June 2009 (SP)        **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 5.954e-9
Ldrain 2 5 1.44e-9
Lsource 3 7 1.972e-9
RLgate 1 9 59.54
RLdrain 2 5 14.4
RLsource 3 7 19.72
Rgate 9 6 1.4
It 7 17 1
Ebreak 11 7 17 7 66
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.75e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=38e-12 n=1 RS=1.05e-3 TRS1=3.0e-3 TRS2=1e-6
+ CJO=4.08e-9 M=0.52 TT=0.1e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.479e-3
Rdrain 5 16 RdrainMOD 0.815e-3
.MODEL RdrainMOD RES (TC1=8.0e-3 TC2=1.8e-5)
M_BSIM3 16 6 7a 7a Bsim3 W=17.635 L=1.58e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1050e-10 ;Oxide thickness
+ XJ=0.89e-6 ;Channel depth
+ NCH=1.2e17 ;Channel concentration
*Channel Current
+ U0=700 VSAT=500000 DROUT=1.8
+ DELTA=0.2 PSCBE2=0.00001 RSH=0.479e-3
*Threshold voltage
+ VTH0=3.4
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.28e-6 DLC=0.28e-6
+ CGSO=187e-12 CGSL=0e-12 CGDO=18e-12 CGDL=265e-12
+ CJ=0 CF=0 CKAPPA=1.25
* Temperature parameters
+ KT1=-2.2 KT2=0 UA1=1.3e-9
+ NJ=10)
.ENDS