*$
*************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDH50N50
** N-Channel UniFET MOSFET
** 500V, 48A, 105mohm
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDH50N50 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 550
Lgate 1 9    1.183e-9
Ldrain 2 5   1.105e-9
Lsource 3 7  1.105e-9
RLgate 1 9   10
RLdrain 2 5  10
RLsource 3 7 10
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=9.78e-4 TC2=-1.98e-6)
.MODEL DbodyMOD D (IS=5.45e-13  N=1      RS=3.12e-3  TRS1=1.92e-3  TRS2=1e-5 
+ CJO=9.62e-9      M=0.66       VJ=0.48  TT=7.52e-7  XTI=3         EG=1.18)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1.0e-6)
Rdrain 5 16 RdrainMOD 0.087
.MODEL RdrainMOD RES (TC1=7.22e-3 TC2=2.05e-5)
M_BSIM3 16 6 7 7 Bsim3 W=13.91 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10    XJ=1.4e-6     NCH=1.36e17
+ U0=600          VSAT=1.0e5    DROUT=10.0
+ DELTA=0.1       PSCBE2=0      RSH=5.12e-4 
+ VTH0=4.55       VOFF=-0.1     NFACTOR=1.1
+ LINT=3.82e-7    DLC=3.82e-7   FC=0.5
+ CGSO=1.05e-15   CGSL=1.0e-15  CGDO=1.0e-14
+ CGDL=4.25e-10   CJ=0          CF=0   
+ CKAPPA=0.01     KT1=-1.28     KT2=0
+ UA1=1.0e-9      NJ=10)
.ENDS
*$
*************** Power Discrete MOSFET Thermal Model ********************
** Package: TO-247
**----------------------------------------------------------------------
.SUBCKT FDH50N50_Thermal TH TL
CTHERM1 TH 6 2.04e-4
CTHERM2 6 5  4.68e-3
CTHERM3 5 4  3.04e-2
CTHERM4 4 3  8.52e-2
CTHERM5 3 2  2.82e-1
CTHERM6 2 TL 8.02e-1
RTHERM1 TH 6 2.40e-4
RTHERM2 6 5  2.90e-3
RTHERM3 5 4  6.34e-3
RTHERM4 4 3  1.38e-2
RTHERM5 3 2  7.46e-2
RTHERM6 2 TL 1.02e-1
.ENDS FDH50N50_Thermal
**---------------------------------------------------------------------
** Creation: Mar.-04-2019   Rev.:1.0
** ON Semiconductor
*$