**************** Power Discrete MOSFET Electrical Parameters *****************
* Product: FDH44N50
* 44A, 500V, 0.12 ohm, N-Channel SMPS MOSFET
* Package: JEDEC TO-247
*--------------------------------------------------------------------------------
.SUBCKT FDH44N50 20 10 30
Rg 10 1 2.25
M1 2 1 3 3 DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO={3.98*{-0.00076*TEMP+1.019}} KP={-0.022*TEMP+95}
+ THETA=0.064   VMAX=3.0E5   LEVEL=3)
Cgs 1 3 4095p
Rd 20 4 0.0487 TC=0.01
Dds 3 4 DDS
.MODEL DDS D(BV={500*{0.000925*TEMP+0.976875}}  M=0.58  CJO=5250p  VJ=0.58)
Dbody 3 20 DBODY
.MODEL DBODY D(IS=2.2E-12  N=1.00  RS=0.0006  EG=1.115  TT=590n)
Ra 4 2 0.0487 TC=0.01
Rs 3 5 0.002
Ls 5 30 0.55n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS (VTO=0 KP=10 LEVEL=1)
CGDmax 7 4 7250p
Rcgd 7 4 1E7
Dgd 6 4 DGD
Rdgd 4 6 1E7
.MODEL DGD D(M=0.48 CJO=7250p VJ=0.00172)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
.ENDS
*--------------------------------------------------------------------------------

********************* Power Discrete MOSFET Thermal Model **********************
.SUBCKT FDH44N50_Thermal TH TL
CTHERM1 TH 6 1.94e-4
CTHERM2 6 5 2.08e-3
CTHERM3 5 4 1.34e-2
CTHERM4 4 3 2.92e-2
CTHERM5 3 2 3.02e-1
CTHERM6 2 TL 3.62e-1

RTHERM1 TH 6 2.0e-4
RTHERM2 6 5  2.5e-3
RTHERM3 5 4  4.2e-3
RTHERM4 4 3  1.9e-2
RTHERM5 3 2  2.4e-2
RTHERM6 2 TL 1.5e-1
.ENDS
*-------------------------------------------------------------------------------
* Creation: Feb.-16-2007     rev: 0.0
* Fairchild Semiconductor