*$
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDH210N08
** 75V N-Channel MOSFET and TO-247
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDH210N08 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 75
Lgate 1 9    4.99e-9
Ldrain 2 5   1.44e-9
Lsource 3 7  2.49e-9
RLgate 1 9   10
RLdrain 2 5  10
RLsource 3 7 10
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.08e-3 TC2=-2.48e-6)
.MODEL DbodyMOD D (IS=6.25e-12 N=1      RS=1.32e-3  TRS1=2.84e-3 TRS2=3.85e-6 
+ CJO=1.29e-8      M=0.52      VJ=0.57  TT=1.28e-7  XTI=3        EG=1.12)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 0.00344
.MODEL RdrainMOD RES (TC1=7.1e-3 TC2=1.7e-5)
M_BSIM3 16 6 7 7 BSIM3 W=19.7 L=2.0e-6 NRS=1
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10     XJ=1.1e-7      NCH=1.04e16
+ U0=700           VSAT=5.0e5     DROUT=1.0
+ DELTA=0.1        PSCBE2=0       RSH=5.29e-4
+ VTH0=3.75        VOFF=-0.1      NFACTOR=1.1
+ LINT=3.18e-7     DLC=3.18e-7    FC=0.5
+ CGSO=8.2e-14     CGSL=0         CGDO=1.0e-12 
+ CGDL=6.85e-10    CJ=0           CF=0
+ CKAPPA=0.072     KT1=-1.04      KT2=0
+ UA1=1.51e-9      NJ=10)
.ENDS
*$
******************* Power Discrete MOSFET Thermal Model *************************
** Package: TO-247
**-------------------------------------------------------------------------------
.SUBCKT FDH210N08_THERMAL TH TL
CTHERM1 TH 6 1.04e-5
CTHERM2 6 5  2.68e-2
CTHERM3 5 4  6.24e-2
CTHERM4 4 3  8.02e-2
CTHERM5 3 2  2.62e-1
CTHERM6 2 TL 6.52e-1
RTHERM1 TH 6 2.40e-4
RTHERM2 6 5  4.80e-3
RTHERM3 5 4  8.24e-3
RTHERM4 4 3  3.28e-2
RTHERM5 3 2  9.66e-2
RTHERM6 2 TL 1.27e-1
.ENDS FDH210N08_THERMAL
**-----------------------------------------------------------------------
** Creation: Feb.-08-2019   Rev.: 1.0
** ON Semiconductor