* PSpice Model Editor - Version 10.5.0
*$
*FDG6342L Electrical Model(Complementary N-Channel)
*--------------------------------------------------
.SUBCKT FDG6342L_NCh 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 5.9e-10
Ldrain 2 5 1.0e-10
Lsource 3 7 7.2e-10
RLgate 1 9 5.9
RLdrain 2 5 1.0
RLsource 3 7 7.2
Rgate 9 6 3.5
It 7 17 1
Ebreak 11 7 17 7 25
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=7.8e-9 n=1.9 RS=2.05e-1 TRS1=5.5e-4 TRS2=0 
+ CJO=3.85e-11 M=0.1 TT=15n XTI=-4)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rsource 7a 7 1.15e-3
Rdrain 5 16 RdrainMOD 1.46
.MODEL RdrainMOD RES (TC1=2.5e-3 TC2=1e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.0034 L=1.6u NRS=1
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.2 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=160e-10 ;Oxide thickness
+ XJ=2.3u ;Channel depth
+ NCH=1.8e17 ;Channel concentration
**Channel Current
+ U0=1100 VSAT=8e5 DROUT=1.1
+ DELTA=0.1 PSCBE2=0 RSH=1.15e-3
**Threshold voltage
+ VTH0=0.8
**Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.2
**Junction diodes and Capacitance
+ LINT=0.065u DLC=0.065u 
+ CGSO=1288p CGSL=0p CGDO=380p CGDL=2238p
+ CJ=0 CF=0 CKAPPA=0.35
** Temperature parameters
+ KT1=-1 KT2=0 UA1=1e-8 
+ NJ=10)
.ENDS
*$
.SUBCKT FDG6342L_PCh 2 1 3
*Nom Temp 25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Lgate 1 9 0.455e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.439e-9
RLgate 1 9 0.455
RLdrain 2 5 1
RLsource 3 7 4.39
Rgate 9 6 9
It 7 17 1
Ebreak 5 11 17 7 -22
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.67e-3 TC2=0.1e-6)
.MODEL DbodyMOD D (IS=0.32e-12 n=1 RS=50e-2 TRS1=1e-3 TRS2=0e-6
+ CJO=3.5e-11 M=0.5 TT=1e-9 XTI=0.1)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 5.8e-3
Rdrain 5 16 RdrainMOD 97e-3
.MODEL RdrainMOD RES (TC1=3.2e-3 TC2=3e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.366 L=1.2e-6 NRS=1 NRD=0
.MODEL Bsim3 PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=160e-10 ;Oxide thickness
+ XJ=0.26e-6 ;Channel depth
+ NCH=1.95e17 ;Channel concentration
*Channel Current
+ U0=250 VSAT=5e5 DROUT=1.8
+ DELTA=0.25 PSCBE2=0.00001 RSH=5.8e-3
*Threshold voltage
+ VTH0=-0.57
*Sub-threshold characteristics
+ VOFF=0.1 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.3e-6 DLC=0.3e-6
+ CGSO=250e-12 CGSL=0 CGDO=1e-12 CGDL=1998e-12
+ CJ=0 CF=0 CKAPPA=0.4
* Temperature parameters
+ KT1=-0.55 KT2=0 UA1=4.5e-9
+ NJ=10)
.ENDS
*FDG6342L(Rev.A) 12/5/2008
*ST
*$