* OrCAD Model Editor - Version 9.1
*$
.SUBCKT FDG332PZ 2 1 3   
*Nom Temp=25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Ebreak 5 11 17 7 -22
Lgate 1 9 0.383e-9
Ldrain 2 5 0.1e-9 
Lsource 3 7 0.241e-9
RLgate 1 9 3.83
RLdrain 2 5 1
RLsource 3 7 2.41
Rgate 9 6 24.7
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=7e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=4.92e-11 n=0.92 RS=3.9e-1 TRS1=5e-8 TRS2=5e-7
+ CJO=0.15e-9 M=0.5 TT=16e-9 XTI=-12)
.MODEL DbreakMOD D (RS=9e-2 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 54e-3 
.MODEL RdrainMOD RES (TC1=4.4e-3 TC2=5e-6)
M_BSIM3 16 6 7 7 M_MOD W=0.64 L=1.2e-6 NRS=1 NRD=0  
.MODEL  M_MOD PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
***Process Parameters
+ TOX=160e-10 ;Oxide thickness
+ XJ=0.26e-6 ;Channel depth 
+ NCH=1.95e17 ;Channel concentration
***Channel Current
+ U0=250 vsat=5e5 drout=1.8 
+ DELTA=0.3 PSCBE2=1e-5 RSH=8.214e-3 
***Threshold voltage
+ VTH0=-0.7
***Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1 
***Junction diodes and Capacitance
+ LINT=0.3e-6 DLC=0.3e-6 
+ CGSO=100e-12 CGSL=0 CGDO=35e-12 CGDL=800e-12 
+ CJ=0 CF=0p CKAPPA=0.32
*** Temperature parameters
+ KT1=-0.73 KT2=0 UA1=0.98E-8
+ NJ=10) 
.ENDS 
*FDG332PZ(Rev.A) 8/9/2007
*ST
*$