* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDFS6N548 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 33
Lgate 1 9 1.412e-9
Ldrain 2 5 1e-9
Lsource 3 7 0.743e-9
RLgate 1 9 14.12
RLdrain 2 5 10
RLsource 3 7 7.43
Rgate 9 6 0.8
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=7.5e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1.29e-12 n=1 RS=13.8e-3 TRS1=1.5e-4 TRS2=0 
+ CJO=2e-10 M=0.4 TT=1e-10 XTI=3)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 13.5e-3
.MODEL RdrainMOD RES (TC1=4.2e-3 TC2=2.8e-6)
M_BSIM3 16 6 7 7 Bsim3 W=0.91 L=0.95e-6 NRS=1 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.46e-6 ;Channel depth
+ NCH=1.43e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e6 DROUT=1.8
+ DELTA=0.1 PSCBE2=1e-5 RSH=2.17e-3   
**Threshold voltage
+ VTH0=1.75
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.175e-6 DLC=0.175e-6 
+ CGSO=150e-12 CGSL=0 CGDO=45e-12 CGDL=180e-12
+ CJ=0 CF=0 CKAPPA=1.8
** Temperature parameters
+ KT1=-1.1 KT2=0 UA1=4.3e-9 
+ NJ=10)
.ENDS
*$
.MODEL FDFS6N548_Schky D BV=30 IS=43e-6 n=1.1 RS=0.032 TRS1=5e-3 
+ XTI=3 EG=0.55
+ NBV=10 CJO=1e-9 M=0.7 TT=1e-10)
*FDFS6N548 (Rev.B) 6/12/07
*ST
*$