*FDFS2P106A at Temp. Electrical Model 
*---------------------------------------------------------
.SUBCKT FDFS2P106A 20 10 30 50
*20=DRAIN 10=GATE 30=SOURCE 50=VTEMP
Rg 10 11x 1
Rdu 12x 1 1u
M1 2 1 4x 4x DMOS L=1u W=1u
.MODEL DMOS PMOS(VTO=-1.92 KP=1.26E+1
+THETA=0.1 VMAX=4.5E5 LEVEL=3)
Cgs 1 5x 700p
Rd 20 4 3.7E-2
Dds 4 5x DDS
.MODEL DDS D(M=5.01E-1 VJ=9.57E-1 CJO=288p)
Dbody 20 5x DBODY
.MODEL DBODY D(IS=3.21E-12 N=1.085452 RS=.00072 TT=22.82n)
Ra 4 2 3.7E-2
Rs 5x 5 0.5m
Ls 5 30 0.5n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER PMOS(VTO=0 KP=10 LEVEL=1)
Cgdmax 7 4 580p
Rcgd 7 4 10meg
Dgd 4 6 DGD
Rdgd 4 6 10meg
.MODEL DGD D(M=3.09E-1 VJ=2.97E-3 CJO=580p)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
*ZX SECTION
EOUT 4x 6x poly(2) (1x,0) (3x,0) 0 0 0 0 1
FCOPY 0 3x VSENSE 1
RIN 1x 0 1G
VSENSE 6x 5x 0
RREF 3x 0 10m
*TEMP SECTION
ED 101 0 VALUE {V(50,100)}
VAMB 100 0 25
EKP 1x 0 101 0 .055
*VTO TEMP SECTION
EVTO 102 0 101 0 .005
EVT 11x 12x 102 0 1
*DIODE THEMO BREAKDOWN SECTION
EBL VB1 VB2 101 0 .08
VBLK VB2 0 60
D DB1 20 DBLK
.MODEL DBLK D(IS=1E-14 CJO=.1p RS=.1)
EDB 0 DB1 VB1 0 1
.ENDS FDFS2P106A 
*****************************************************
*FDFS2P106A/FCSB360  Schottky Diode 
*****************************************************
.MODEL FDFS2P106A_SCH  D  
+ IS = 2.7E-7
+ RS = 0.031204
+ N = 1.0754141
+ XTI = 2
+ EG = 0.69
+ BV = 45
+ IBV = 1.0E-03
*FDFS2P106A (Rev.B) 5/12/05 
*ST