.SUBCKT FDFME3N311ZT 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDFME3N311ZT Spice model                **
**                    Revision RevA, 21 Oct 2010                **
**        Revision RevB, 24 May 2011   Schottky diode added     **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.75e-9
Ldrain 2 5 0.011e-9
Lsource 3 7 0.435e-9
RLgate 1 9 7.5
RLdrain 2 5 0.11
RLsource 3 7 4.35
Rgate 9 6 3.27
It 7 17 1
Ebreak 11 7 17 7 32.9
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.84e-3 TC2=-0.5e-6)
.MODEL DbodyMOD D (IS=20e-12 n=1.15 RS=105e-3 TRS1=0.5e-3 TRS2=1e-6
+ CJO=0.017e-9 M=0.68 TT=0.1e-9 XTI=1.25)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 77 7 11.323e-3
Rdrain 5 16 RdrainMOD 175e-3
.MODEL RdrainMOD RES (TC1=4.7e-3 TC2=11e-6)
M_BSIM3 16 6 77 77 Bsim3 W=0.063 L=1.05e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=240e-10 ;Oxide thickness
+ XJ=0.52e-6 ;Channel depth
+ NCH=1.32e17 ;Channel concentration
*Channel Current
+ U0=750 VSAT=200000 DROUT=2.5
+ DELTA=0.05 PSCBE2=0.00001 RSH=11.323e-3
*Threshold voltage
+ VTH0=1.0
*Sub-threshold characteristics
+ VOFF=-0.11 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.18e-6 DLC=0.19e-6
+ CGSO=542e-12 CGSL=0 CGDO=45e-12 CGDL=680e-12
+ CJ=0 CF=0 CKAPPA=0.4
* Temperature parameters
+ KT1=-0.75 KT2=0 UA1=6e-9
+ NJ=10)
.ENDS FDFME3N311ZT


.MODEL FDFME3N311ZT_Schottky D (BV=30 IS=7.0e-6 n=1.1 RS=0.17 TRS1=5.4e-3 
+ XTI=3 EG=0.6
+ NBV=10 CJO=1.5e-10 M=0.4 TT=12e-9)