.SUBCKT FDFMA3N109 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2011 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDFMA3N109 Spice model                  **
**                    Revision RevB, 20 Jun 2007                **
******************************************************************
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.56e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.22e-9
RLgate 1 9 5.6
RLdrain 2 5 1
RLsource 3 7 2.2
Rgate 9 6 4.5
It 7 17 1
Ebreak 11 7 17 7 32.3
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8.4e-4 TC2=1e-7)
.MODEL DbodyMOD D (IS=8.28e-11 n=1.17 RS=3.7e-2 TRS1=1.8e-3 TRS2=0 
+ CJO=4.9e-11 M=0.1 TT=1e-10 XTI=0.1)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 54.5e-3
.MODEL RdrainMOD RES (TC1=3.9e-3 TC2=1.0e-5)
M_BSIM3 16 6 7 7 Bsim3 W=0.256 L=0.98e-6 NRS=1 NRD=0
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=240e-10 ;Oxide thickness
+ XJ=0.52e-6 ;Channel depth
+ NCH=1.32e17 ;Channel concentration
*Channel Current
+U0=620 VSAT=1.4e5 DROUT=2.5
+ DELTA=0.02 PSCBE2=1e-5 RSH=6.15e-3   
*Threshold voltage
+ VTH0=0.96
*Sub-threshold characteristics
+ VOFF=-0.0 NFACTOR=1.7
*Junction diodes and Capacitance
+ LINT=0.165e-6 DLC=0.165e-6 
+ CGSO=70e-12 CGSL=0 CGDO=20e-12 CGDL=700e-12
+ CJ=0 CF=0 CKAPPA=0.5
* Temperature parameters
+ KT1=-0.7 KT2=0 UA1=5.0e-9
+ NJ=10)
.ends FDFMA3N109

.MODEL FDFMA3N109_Schottky D (BV=30 IS=7.0e-6 n=1.1 RS=0.17 TRS1=5.4e-3 
+ XTI=3 EG=0.6 NBV=10 CJO=1.5e-10 M=0.4 TT=12e-9)