.SUBCKT FDFMA2P859T 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDFMA2P859T Spice model                 **
**                    Revision RevA, 13 May 2010                **
******************************************************************
*Nom Temp=25 deg C
*Monte Carlo capable
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Lgate 1 9 0.54e-9
Ldrain 2 5 0.5e-9 
Lsource 3 7 0.26e-9
RLgate 1 9 5.4
RLdrain 2 5 5
RLsource 3 7 2.6
Rgate 9 6 7.5
It 7 17 1
Ebreak 5 11 17 7 -22.3
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=7.2e-4 TC2=-2e-7)
.MODEL DbodyMOD D (IS=40.5e-11 n=1.2 RS=42m TRS1=1e-4 TRS2=2e-6
+ CJO=1.4e-10 M=0.25 VJ=0.45 TT=2.1e-9 XTI=1 IKF=0.1)
.MODEL DbreakMOD D (RS=0.35 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 54e-3
.MODEL RdrainMOD RES (TC1=2.3e-3 TC2=4e-6 R=1 DEV=13%)
M_BSIM3 16 6 7 7 Bsim3 W=0.292 L=1.21u NRS=1 NRD=0
.MODEL  Bsim3 PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=160e-10 DEV=8% ;Oxide thickness
+ XJ=0.9u ;Channel depth
+ NCH=2e17 ;Channel concentration
*Channel Current
+U0=200 vsat=10e5 drout=2
+ DELTA=0.25 PSCBE2=1e-5 RSH=7.6e-3
*Threshold voltage
+ VTH0=-0.58 DEV=8%
*Sub-threshold characteristics
+ VOFF=-0.15 NFACTOR=1.0
*Junction diodes and Capacitance
+ LINT=0.37u DLC=0.37u DEV=18%
+ CGSO=790p CGSL=0p CGDO=8p CGDL=780p DEV=4%
+ CJ=0 CF=0 CKAPPA=0.9 
* Temperature parameters
+ KT1=-0.6 KT2=0 UA1=2.0e-9
+ NJ=10)
.ENDS 

.MODEL FDFMA2P859T_Diode  D  (IS=10e-6 RS=63e-3 TRS1=2.8e-3 N=1.1 XTI=2.5
+ EG=0.65 BV=22 NBV=100 IBV=1e-03
+ CJO=163e-12 VJ=0.42 M=0.3 TT=2.4e-9)
*FDFMA2P859T Schottky Diode Model