* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDFMA2N028Z 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 22
Lgate 1 9 0.45e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.19e-9
RLgate 1 9 4.5
RLdrain 2 5 1
RLsource 3 7 1.9
Rgate 9 6 2.1
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-5e-7)
.MODEL DbodyMOD D (IS=2.6e-11 n=1.1 RS=2.5e-2 TRS1=1.1e-4 TRS2=0 
+ CJO=1.2e-10 M=0.35 TT=5n XTI=0.5)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 23m
.MODEL RdrainMOD RES (TC1=8e-4 TC2=1e-6)
M_BSIM3 16 6 7 7 Bsim3 W=0.43 L=1.1u NRS=1
.MODEL  Bsim3 NMOS ( LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
**Process Parameters
+ TOX=240e-10 ;Oxide thickness
+ XJ=0.52u ;Channel depth
+ NCH=1.2e17 ;Channel concentration
**Channel Current
+ U0=500 VSAT=5e6 DROUT=1.5
+ DELTA=0.5 PSCBE2=0 RSH=0.3m   
**Threshold voltage
+ VTH0=1.15
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.2
**Junction diodes and Capacitance
+ LINT=0.25u DLC=0.25u 
+ CGSO=200p CGSL=0 CGDO=100p CGDL=324p
+ CJ=0 CF=0 CKAPPA=1
** Temperature parameters
+ KT1=-1 KT2=0 UA1=1e-8 
+ NJ=10
.ENDS
*$
*********************************************************
.MODEL FDFMA2N028Z_Schottky D (BV=21 IS=8.4e-6 n=1 RS=0.065 TRS1=5.45e-3 
+ XTI=1 EG=0.6
+ NBV=10 CJO=2.5e-10 M=0.4 TT=12e-9)
*FDFMA2N028Z (Rev.A) 1/4/07
*ST
*$