*FDFM2N111 at Temp. Electrical Model
*---------------------------------------------------------
.SUBCKT FDFM2N111 20 10 30 50
*20=DRAIN 10=GATE 30=SOURCE 50=VTEMP
Rg 10 11x 1
Rdu 12x 1 1u
M1 2 1 4x 4x DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO=1 KP=1.21E+1
+THETA=.133333 VMAX=1.8E5 LEVEL=3)
Cgs 1 5x 242p
Rd 20 4 1E-2
Dds 5x 4 DDS
.MODEL DDS D(M=4.56E-1 VJ=7.97E-1 CJO=84p)
Dbody 5x 20 DBODY
.MODEL DBODY D(IS=9.75E-12 N=1.083638 RS=5.1E-4 TT=25n)
Ra 4 2 1E-2
Rs 5x 5 0.5m
Ls 5 30 0.5n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS(VTO=0 KP=10 LEVEL=1)
Cgdmax 7 4 243p
Rcgd 7 4 10meg
Dgd 6 4 DGD
Rdgd 6 4 10meg
.MODEL DGD D(M=3.08E-1 VJ=2.25E-2 CJO=243p)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
*ZX SECTION
EOUT 4x 6x poly(2) (1x,0) (3x,0) 0 0 0 0 1
FCOPY 0 3x VSENSE 1
RIN 1x 0 1G
VSENSE 6x 5x 0
RREF 3x 0 10m
*TEMP SECTION
ED 101 0 VALUE {V(50,100)}
VAMB 100 0 25
EKP 1x 0 101 0 .018
*VTO TEMP SECTION
EVTO 102 0 101 0 .0007
EVT 12x 11x 102 0 1
*DIODE THEMO BREAKDOWN SECTION
EBL VB1 VB2 101 0 .08
VBLK VB2 0 20
D 20 DB1 DBLK
.MODEL DBLK D(IS=1E-14 CJO=.1p RS=.1)
EDB DB1 0 VB1 0 1
.ENDS FDFM2N111
*****************************************************
*FDFM2N111/TLBFA Schottky Diode 
*****************************************************
.MODEL TLBFA_SCH  D  
+ IS = 2.09E-5
+ RS = 0.046489
+ N = 1.11406
+ XTI = 2
+ EG = 0.45
+ BV = 20
+ IBV = 1.0E-03
*FDFM2N111 (Rev.A) 4/13/05
*ST