**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FDD8N50NZ
** 500V N-Channel MOSFET and D-PAK
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FDD8N50NZ 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 500
Lgate 1 9    1.12e-9
Ldrain 2 5   1.45e-9
Lsource 3 7  9.66e-10
RLgate 1 9   11.2
RLdrain 2 5  14.5
RLsource 3 7 9.6
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.01e-3 TC2=-4.6e-7)
.MODEL DbodyMOD D (IS=6.45e-13  N=1      RS=1.28e-2  TRS1=1.32e-3  TRS2=1.8e-5 
+ CJO=7.08e-10     M=0.52       VJ=0.47  TT=5.61e-7  XTI=3         EG=1.18)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1.0e-6)
Rdrain 5 16 RdrainMOD 0.77
.MODEL RdrainMOD RES (TC1=8.35e-3 TC2=2.75e-5)
M_BSIM3 16 6 7 7 Bsim3 W=1.52 L=2.0e-6 NRS=1
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=1100e-10    XJ=1.4e-6      NCH=1.4e17
+ U0=700          VSAT=5.0e5     DROUT=1.0
+ DELTA=0.10      PSCBE2=0       RSH=1.09e-3 
+ VTH0=4.25       VOFF=-0.1      NFACTOR=1.1
+ LINT=4.42e-7    DLC=4.42e-7    FC=0.5
+ CGSO=1.05e-15   CGSL=1.0e-15   CGDO=1.0e-15
+ CGDL=3.24e-10   CJ=0           CF=0   
+ CKAPPA=0.2      KT1=-2.40      KT2=0
+ UA1=-1.0e-10    NJ=10)
.ENDS

*************** Power Discrete MOSFET Thermal Model ********************
.SUBCKT FDD8N50NZ_Thermal TH TL
CTHERM1 TH 6 2.24e-5
CTHERM2 6 5  7.08e-4
CTHERM3 5 4  2.64e-3
CTHERM4 4 3  4.82e-3
CTHERM5 3 2  6.42e-3
CTHERM6 2 TL 1.02e-2
RTHERM1 TH 6 4.38e-3
RTHERM2 6 5  1.88e-2
RTHERM3 5 4  8.58e-2
RTHERM4 4 3  1.07e-1
RTHERM5 3 2  3.51e-1
RTHERM6 2 TL 8.33e-1
.ENDS FDD8N50NZ_Thermal
**---------------------------------------------------------------------
** Creation: Dec.-15-2011   Rev.:0.0
** Fairchild Semiconductor