*$
.SUBCKT FDD8876  2 1 3      
*Nom Temp=25 deg C 
*14 May 03

Ca 12 8 1.9e-9
Cb 15 14 1.6e-9
Cin 6 8 1.55e-9

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 33.15
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 4.7e-9
Ldrain 2 5 1.0e-9
Lsource 3 7 1.7e-9

RLgate 1 9 47
RLdrain 2 5 10
RLsource 3 7 17

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD    

Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 2.9e-3
Rgate 9 20 2.2
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 2.7e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*300),10))}

.MODEL DbodyMOD D (IS=3E-12 IKF=10 N=1.01 RS=3.4e-3 TRS1=8e-4 TRS2=2e-7
+ CJO=6.3e-10 M=0.57 TT=1e-17 XTI=2)
.MODEL DbreakMOD D (RS=1 TRS1=1e-3 TRS2=-8.9e-6)
.MODEL DplcapMOD D (CJO=6.1e-10 IS=1e-30 N=10 M=0.41)

.MODEL MmedMOD NMOS (VTO=1.95 KP=10 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=2.2 T_ABS=25)
.MODEL MstroMOD NMOS (VTO=2.45 KP=250 IS=1e-30 N=10 TOX=1 L=1u W=1u T_ABS=25)
.MODEL MweakMOD NMOS (VTO=1.65 KP=0.05 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=22 RS=0.1 T_ABS=25) 

.MODEL RbreakMOD RES (TC1=8.3e-4 TC2=-8e-7)
.MODEL RdrainMOD RES (TC1=1e-4 TC2=8e-6)
.MODEL RSLCMOD RES (TC1=9e-4 TC2=1e-6)
.MODEL RsourceMOD RES (TC1=7.5e-3 TC2=1e-6)
.MODEL RvthresMOD RES (TC1=-1.7e-3 TC2=-8.2e-6)
.MODEL RvtempMOD RES (TC1=-2.6e-3 TC2=2e-7)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-4 VOFF=-3.5)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-3.5 VOFF=-4)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2 VOFF=-1.5)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-1.5 VOFF=-2)

.ENDS
*$


*Thermal Model Subcircuit
.SUBCKT FDD8876T TH TL
*Thermal Model Subcircuit
*14 May 03

CTHERM1 TH 6 7e-4
CTHERM2 6 5 9e-4
CTHERM3 5 4 2e-3
CTHERM4 4 3 2.5e-3
CTHERM5 3 2 6e-3
CTHERM6 2 TL 1.1e-2

RTHERM1 TH 6 7.0e-2
RTHERM2 6 5 1.1e-1
RTHERM3 5 4 2.2e-1
RTHERM4 4 3 3.2e-1
RTHERM5 3 2 4.9e-1
RTHERM6 2 TL 5e-1



.ends



*$