.SUBCKT FDD86540 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2011 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                   FDD86540 Spice model (60V, 50A)            **
**                    Revision Rev-A, 06 Feb 2012               **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.155e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.353e-9
RLgate 1 9 21.55
RLdrain 2 5 0.04
RLsource 3 7 3.53
Rgate 9 6 0.49
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.46
C_C1 6 101 655e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=4.44e-9 M=0.41 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 66
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.47e-3 TC2=-0.55e-6)
.MODEL DbodyMOD D (IS=5.0e-12 n=1 RS=2.0e-3 TRS1=1.05e-3 TRS2=1e-6 
+ CJO=1.12e-9 M=0.275 TT=3e-9 XTI=1.9)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.493e-3
Rdrain 5 16 RdrainMOD 2.0e-3
.MODEL RdrainMOD RES (TC1=5.5e-3 TC2=16.8e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=7.33 L=0.96e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10 
+ XJ=0.28e-6 
+ NCH=2e17 
+ U0=1050 VSAT=500000 DROUT=1.2
+ DELTA=0.14 PSCBE2=0 RSH=0.493e-3
+ VTH0=2.5
+ VOFF=-0.1 NFACTOR=1
+ LINT=0.16e-6 DLC=0.16e-6 
+ CGSO=356e-12 CGSL=0 CGDO=1e-12 CGDL=155e-12 
+ CJ=0 CF=0 CKAPPA=1
+ KT1=-2.1 KT2=0 UA1=1e-9
+ NJ=10)
.ENDS