* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDD8647L 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 5.216e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 2.722e-9
RLgate 1 9 52.16
RLdrain 2 5 1
RLsource 3 7 27.22
Rgate 9 6 0.9
It 7 17 1
Ebreak 11 7 17 7 44
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.75e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=0.85e-12 n=1 RS=2.95e-3 TRS1=2.5e-3 TRS2=1e-6
+ CJO=0.89e-9 M=0.35 TT=10.85e-9 XTI=3)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=0)
Rsource 7a 7 1.168e-3
Rdrain 5 16 RdrainMOD 4.85e-3
.MODEL RdrainMOD RES (TC1=5e-3 TC2=5e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.22 L=0.91e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS(LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.675e-6 ;Channel depth
+ NCH=1.9e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1.2
+ DELTA=0.1 PSCBE2=1e-5 RSH=1.168e-3  
**Threshold voltage
+ VTH0=1.85
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.14e-6 DLC=0.14e-6 
+ CGSO=92e-12 CGSL=0 CGDO=3.5e-12 CGDL=188e-12
+ CJ=0 CF=0 CKAPPA=1.5
** Temperature parameters
+ KT1=-1.1 KT2=0 UA1=1.5e-9
+ NJ=10)
.ENDS
*FDD8647L(Rev.A) 01/08/2009
*ST
*$